mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
python, python-native: upgrade from 2.6.6 to 2.7.2
Rebased these patches to the newer code modified: python-native/nohostlibs.patch modified: python/01-use-proper-tools-for-cross-build.patch modified: python/06-avoid_usr_lib_termcap_path_in_linking.patch modified: python/06-ctypes-libffi-fix-configure.patch modified: python/multilib.patch Deleted these patches are the are now upstream deleted: python/02-remove-test-for-cross.patch deleted: python/security_issue_2254_fix.patch Added this patch to python-native new file: python-native/multilib.patch Updated site config file for python modified: ../../site/common-linux : add ac_cv_have_long_long_format for python avoid this error in python: Include/pyport.h:243:13: error: #error "This platform's pyconfig.h needs to define PY_FORMAT_LONG_LONG" Updated default python version modified: ../../conf/distro/include/default-versions.inc (From OE-Core rev: b284e9a512860b8a8380be80f96cebce6b92ff80) Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
This commit is contained in:
Nitin A Kamble
committed by
Richard Purdie
Richard Purdie
parent
0d18f03b22
commit
01103b2f29
144
meta/recipes-devtools/python/python_2.7.2.bb
Normal file
144
meta/recipes-devtools/python/python_2.7.2.bb
Normal file
@@ -0,0 +1,144 @@
|
||||
require python.inc
|
||||
DEPENDS = "python-native db gdbm openssl readline sqlite3 zlib"
|
||||
DEPENDS_sharprom = "python-native db readline zlib gdbm openssl"
|
||||
PR = "${INC_PR}.0"
|
||||
|
||||
DISTRO_SRC_URI ?= "file://sitecustomize.py"
|
||||
DISTRO_SRC_URI_linuxstdbase = ""
|
||||
SRC_URI += "\
|
||||
file://01-use-proper-tools-for-cross-build.patch \
|
||||
file://03-fix-tkinter-detection.patch \
|
||||
file://04-default-is-optimized.patch \
|
||||
file://05-enable-ctypes-cross-build.patch \
|
||||
file://06-ctypes-libffi-fix-configure.patch \
|
||||
file://06-avoid_usr_lib_termcap_path_in_linking.patch \
|
||||
file://07-linux3-regen-fix.patch \
|
||||
file://99-ignore-optimization-flag.patch \
|
||||
${DISTRO_SRC_URI} \
|
||||
file://multilib.patch \
|
||||
file://cgi_py.patch \
|
||||
file://remove_sqlite_rpath.patch \
|
||||
"
|
||||
|
||||
S = "${WORKDIR}/Python-${PV}"
|
||||
|
||||
inherit autotools
|
||||
|
||||
# The 3 lines below are copied from the libffi recipe, ctypes ships its own copy of the libffi sources
|
||||
#Somehow gcc doesn't set __SOFTFP__ when passing -mfloatabi=softp :(
|
||||
TARGET_CC_ARCH_append_armv6 = " -D__SOFTFP__"
|
||||
TARGET_CC_ARCH_append_armv7a = " -D__SOFTFP__"
|
||||
|
||||
do_configure_prepend() {
|
||||
autoreconf -Wcross --verbose --install --force --exclude=autopoint Modules/_ctypes/libffi || bbnote "_ctypes failed to autoreconf"
|
||||
}
|
||||
|
||||
do_compile() {
|
||||
#
|
||||
# Copy config.h and an appropriate Makefile for distutils.sysconfig,
|
||||
# which laters uses the information out of these to compile extensions
|
||||
#
|
||||
# The following part (until python compilation) should probably moved to an
|
||||
# -initial recipe to handle staging better
|
||||
#
|
||||
install -d ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
|
||||
install -d ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
|
||||
install -m 0644 pyconfig.h ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
|
||||
|
||||
# remove hardcoded ccache, see http://bugs.openembedded.net/show_bug.cgi?id=4144
|
||||
sed -i -e s,ccache,'$(CCACHE)', Makefile
|
||||
|
||||
install -m 0644 Makefile Makefile.orig
|
||||
sed -i -e 's,${includedir},${STAGING_INCDIR},' Makefile
|
||||
sed -i -e 's,${libdir},${STAGING_LIBDIR},' Makefile
|
||||
install -m 0644 Makefile ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
|
||||
# save copy of it now, because if we do it in do_install and
|
||||
# then call do_install twice we get Makefile.orig == Makefile.sysroot
|
||||
install -m 0644 Makefile Makefile.sysroot
|
||||
|
||||
oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
|
||||
HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
|
||||
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
||||
STAGING_INCDIR=${STAGING_INCDIR} \
|
||||
BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
|
||||
OPT="${CFLAGS}" libpython${PYTHON_MAJMIN}.so
|
||||
|
||||
oe_libinstall -so libpython${PYTHON_MAJMIN} ${STAGING_LIBDIR}
|
||||
|
||||
oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
|
||||
HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
|
||||
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
||||
STAGING_INCDIR=${STAGING_INCDIR} \
|
||||
BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
|
||||
OPT="${CFLAGS}"
|
||||
}
|
||||
|
||||
do_install() {
|
||||
# make install needs the original Makefile, or otherwise the inclues would
|
||||
# go to ${D}${STAGING...}/...
|
||||
install -m 0644 Makefile.orig Makefile
|
||||
|
||||
oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
|
||||
HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
|
||||
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
||||
STAGING_INCDIR=${STAGING_INCDIR} \
|
||||
BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
|
||||
DESTDIR=${D} LIBDIR=${libdir} install
|
||||
|
||||
install -m 0644 Makefile.sysroot ${D}/${libdir}/python${PYTHON_MAJMIN}/config/Makefile
|
||||
|
||||
if [ -e ${WORKDIR}/sitecustomize.py ]; then
|
||||
install -m 0644 ${WORKDIR}/sitecustomize.py ${D}/${libdir}/python${PYTHON_MAJMIN}
|
||||
fi
|
||||
}
|
||||
|
||||
PACKAGE_PREPROCESS_FUNCS += "py_package_preprocess"
|
||||
|
||||
py_package_preprocess () {
|
||||
# copy back the old Makefile to fix target package
|
||||
install -m 0644 Makefile.orig ${PKGD}/${libdir}/python${PYTHON_MAJMIN}/config/Makefile
|
||||
}
|
||||
|
||||
require python-${PYTHON_MAJMIN}-manifest.inc
|
||||
|
||||
# manual dependency additions
|
||||
RPROVIDES_${PN}-core = "${PN}"
|
||||
RRECOMMENDS_${PN}-core = "${PN}-readline"
|
||||
RRECOMMENDS_${PN}-crypt = "openssl"
|
||||
|
||||
# add sitecustomize
|
||||
FILES_${PN}-core += "${libdir}/python${PYTHON_MAJMIN}/sitecustomize.py"
|
||||
# ship 2to3
|
||||
FILES_${PN}-core += "${bindir}/2to3"
|
||||
|
||||
# package libpython2
|
||||
PACKAGES =+ "lib${BPN}2"
|
||||
FILES_lib${BPN}2 = "${libdir}/libpython*.so.*"
|
||||
|
||||
# additional stuff -dev
|
||||
|
||||
FILES_${PN}-dev = "\
|
||||
${includedir} \
|
||||
${libdir}/lib*${SOLIBSDEV} \
|
||||
${libdir}/*.la \
|
||||
${libdir}/*.a \
|
||||
${libdir}/*.o \
|
||||
${libdir}/pkgconfig \
|
||||
${base_libdir}/*.a \
|
||||
${base_libdir}/*.o \
|
||||
${datadir}/aclocal \
|
||||
${datadir}/pkgconfig \
|
||||
"
|
||||
|
||||
# catch debug extensions (isn't that already in python-core-dbg?)
|
||||
FILES_${PN}-dbg += "${libdir}/python${PYTHON_MAJMIN}/lib-dynload/.debug"
|
||||
|
||||
# catch all the rest (unsorted)
|
||||
PACKAGES += "${PN}-misc"
|
||||
FILES_${PN}-misc = "${libdir}/python${PYTHON_MAJMIN}"
|
||||
|
||||
# catch manpage
|
||||
PACKAGES += "${PN}-man"
|
||||
FILES_${PN}-man = "${datadir}/man"
|
||||
|
||||
BBCLASSEXTEND = "nativesdk"
|
||||
Reference in New Issue
Block a user