python3-numpy: upgrade 2.3.1 -> 2.3.2

Release notes (https://github.com/numpy/numpy/releases/tag/v2.3.2): |The NumPy 2.3.2 release is a patch release with a number of bug fixes |and maintenance updates. The highlights are: | | Wheels for Python 3.14.0rc1 | PyPy updated to the latest stable release | OpenBLAS updated to 0.3.30 | |This release supports Python versions 3.11-3.14 Reproducibility OK: |2025-08-28 05:50:44,703 - oe-selftest - INFO - ---------------------------------------------------------------------- |2025-08-28 05:50:44,703 - oe-selftest - INFO - Ran 1 test in 1440.103s |2025-08-28 05:50:44,703 - oe-selftest - INFO - OK |2025-08-28 05:50:49,531 - oe-selftest - INFO - RESULTS: |2025-08-28 05:50:49,531 - oe-selftest - INFO - RESULTS - reproducible.ReproducibleTests.test_reproducible_builds: PASSED (1400.47s) |2025-08-28 05:50:49,724 - oe-selftest - INFO - SUMMARY: |2025-08-28 05:50:49,724 - oe-selftest - INFO - oe-selftest () - Ran 1 test in 1440.103s |2025-08-28 05:50:49,724 - oe-selftest - INFO - oe-selftest - OK - All required tests passed (successes=1, skipped=0, failures=0, errors=0) ptests OK: |============================================================================ |Testsuite summary |# TOTAL: 48921 |# PASS: 46457 |# SKIP: 2426 |# XFAIL: 33 |# FAIL: 0 |# XPASS: 5 |# ERROR: 0 |DURATION: 193 |END: /usr/lib/python3-numpy/ptest |2025-08-28T09:14 |STOP: ptest-runner |TOTAL: 1 FAIL: 0 |root@qemux86-64:~# (From OE-Core rev: 457ed4e564cc4535694aea8faa55a992419be07c) Signed-off-by: Trevor Gamblin <tgamblin@baylibre.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
2026-02-08 01:36:38 +01:00 · 2025-08-28 06:18:56 -04:00
parent d4b5fb23bb
commit 218348be56
1 changed files with 1 additions and 1 deletions
--- a/meta/recipes-devtools/python/python3-numpy_2.3.2.bb
+++ b/meta/recipes-devtools/python/python3-numpy_2.3.2.bb
@@ -0,0 +1,79 @@
+SUMMARY = "A sophisticated Numeric Processing Package for Python"
+HOMEPAGE = "https://numpy.org/"
+DESCRIPTION = "NumPy is the fundamental package needed for scientific computing with Python."
+SECTION = "devel/python"
+LICENSE = "BSD-3-Clause & BSD-2-Clause & PSF-2.0 & Apache-2.0 & MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=26080bf81b2662c7119d3ef28ae197fd"
+
+SRCNAME = "numpy"
+
+SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${SRCNAME}-${PV}.tar.gz \
+           file://0001-Don-t-search-usr-and-so-on-for-libraries-by-default-.patch \
+           file://fix_reproducibility.patch \
+           file://run-ptest \
+           "
+SRC_URI[sha256sum] = "e0486a11ec30cdecb53f184d496d1c6a20786c81e55e41640270130056f8ee48"
+
+GITHUB_BASE_URI = "https://github.com/numpy/numpy/releases"
+UPSTREAM_CHECK_REGEX = "releases/tag/v?(?P<pver>\d+(\.\d+)+)$"
+
+inherit pkgconfig ptest python_mesonpy github-releases cython
+
+S = "${UNPACKDIR}/numpy-${PV}"
+
+PACKAGECONFIG[svml] = "-Ddisable-svml=false,-Ddisable-svml=true"
+
+# the overflow tests fail with compiler-rt on aarch64
+LDFLAGS:append:toolchain-clang:aarch64 = " -rtlib=libgcc -unwindlib=libgcc"
+
+# Remove references to buildpaths from numpy's __config__.py
+do_install:append() {
+    sed -i \
+        -e 's|${S}=||g' \
+        -e 's|${B}=||g' \
+        -e 's|${RECIPE_SYSROOT_NATIVE}=||g' \
+        -e 's|${RECIPE_SYSROOT_NATIVE}||g' \
+        -e 's|${RECIPE_SYSROOT}=||g' \
+        -e 's|${RECIPE_SYSROOT}||g' ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/__config__.py
+
+    nativepython3 -mcompileall -s ${D} ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/__config__.py
+}
+
+FILES:${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/numpy/_core/lib/*.a \
+                          ${PYTHON_SITEPACKAGES_DIR}/numpy/random/lib/*.a \
+"
+
+# install what is needed for numpy.test()
+RDEPENDS:${PN} = "\
+                  python3-compression \
+                  python3-ctypes \
+                  python3-datetime \
+                  python3-difflib \
+                  python3-doctest \
+                  python3-email \
+                  python3-json \
+                  python3-misc \
+                  python3-mmap \
+                  python3-multiprocessing \
+                  python3-netclient \
+                  python3-numbers \
+                  python3-pickle \
+                  python3-pkgutil \
+                  python3-pprint \
+                  python3-pydoc \
+                  python3-shell \
+                  python3-threading \
+                  python3-unittest \
+"
+RDEPENDS:${PN}-ptest += "\
+                         ldd \
+                         meson \
+                         python3-hypothesis \
+                         python3-pytest \
+                         python3-resource \
+                         python3-sortedcontainers \
+                         python3-typing-extensions \
+                         python3-unittest-automake-output \
+"
+
+BBCLASSEXTEND = "native nativesdk"