mirror of
https://git.yoctoproject.org/poky
synced 2026-09-13 00:49:33 +02:00
ghostscript: upgrade to 9.14
- The LICENSE added AGPL for the font files (in Resource/Font); - Rebase ghostscript-9.02-parallel-make.patch to 9.14 - Rebase ghostscript-native-fix-disable-system-libtiff.patch since base/configure.ac has been moved to configure.ac. http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=f1488c5aff54f37ee67759827d4298592af5dbc8 - Obsolete ghostscript-9.05-NOT-check-endian.patch, and add option '--enable-little-endian'/'--enable-big-endian' conditionally to intead. http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=e76dc46756e89a14a3348bce12a633d32e4fa831 - Add base-genht.c-add-a-preprocessor-define-to-allow-fope.patch for native, since the upstream replace all fopen calls with gp_fopen and add a preprocessor define so that any unintential calls directly to fopen will cause an error. This patch add a preprocessor define to allow fopen calling in base/genht.c as exceptions. http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=773c69e46e70bdd5482676437dafd2ca83397643 - Remove package ghostscript-cups, since CUPS filters gstoraster and gstopxl has been moved to cups-filters which is a free software package hosted by OpenPrinting. http://git.ghostscript.com/?p=ghostpdl.git;a=commitdiff;h=9304a21699a6c17579fae32f44f5c92a37c13e2d http://www.linuxfoundation.org/collaborate/workgroups/openprinting/cups-filters (From OE-Core rev: 44ad25519b8e290f9a98b88eeec52ba199e76431) Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
This commit is contained in:
Hongxu Jia
committed by
Richard Purdie
Richard Purdie
parent
1709ec7db7
commit
24ca3ae7c6
104
meta/recipes-extended/ghostscript/ghostscript_9.14.bb
Normal file
104
meta/recipes-extended/ghostscript/ghostscript_9.14.bb
Normal file
@@ -0,0 +1,104 @@
|
||||
SUMMARY = "The GPL Ghostscript PostScript/PDF interpreter"
|
||||
DESCRIPTION = "Ghostscript is used for PostScript/PDF preview and printing. Usually as \
|
||||
a back-end to a program such as ghostview, it can display PostScript and PDF \
|
||||
documents in an X11 environment. \
|
||||
\
|
||||
Furthermore, it can render PostScript and PDF files as graphics to be printed \
|
||||
on non-PostScript printers. Supported printers include common \
|
||||
dot-matrix, inkjet and laser models. \
|
||||
\
|
||||
Package gsfonts contains a set of standard fonts for Ghostscript. \
|
||||
"
|
||||
HOMEPAGE = "http://www.ghostscript.com"
|
||||
SECTION = "console/utils"
|
||||
|
||||
LICENSE = "GPLv3"
|
||||
LIC_FILES_CHKSUM = "file://LICENSE;md5=aad21ea85123608e6a0a58d54ee23567"
|
||||
|
||||
DEPENDS = "ghostscript-native tiff jpeg fontconfig cups"
|
||||
DEPENDS_class-native = ""
|
||||
|
||||
SRC_URI_BASE = "http://downloads.ghostscript.com/public/ghostscript-${PV}.tar.gz"
|
||||
|
||||
SRC_URI = "${SRC_URI_BASE} \
|
||||
file://ghostscript-9.02-prevent_recompiling.patch \
|
||||
file://ghostscript-9.02-genarch.patch \
|
||||
file://objarch.h \
|
||||
file://ghostscript-9.02-parallel-make.patch \
|
||||
"
|
||||
|
||||
SRC_URI_class-native = "${SRC_URI_BASE} \
|
||||
file://ghostscript-native-fix-disable-system-libtiff.patch \
|
||||
file://base-genht.c-add-a-preprocessor-define-to-allow-fope.patch \
|
||||
"
|
||||
|
||||
SRC_URI[md5sum] = "586494befb443363338c1b6379f13973"
|
||||
SRC_URI[sha256sum] = "ab2ba5ce11c8db396c9acf774a497182d7686d04670976cc3e690ada7db9f0d4"
|
||||
|
||||
EXTRA_OECONF = "--without-x --with-system-libtiff --without-jbig2dec \
|
||||
--with-fontpath=${datadir}/fonts \
|
||||
--without-libidn --with-cups-serverbin=${exec_prefix}/lib/cups \
|
||||
--with-cups-datadir=${datadir}/cups \
|
||||
${@base_conditional('SITEINFO_ENDIANNESS', 'le', '--enable-little-endian', '--enable-big-endian', d)} \
|
||||
"
|
||||
|
||||
# Explicity disable libtiff, fontconfig,
|
||||
# freetype, cups for ghostscript-native
|
||||
EXTRA_OECONF_class-native = "--without-x --with-system-libtiff=no \
|
||||
--without-jbig2dec \
|
||||
--with-fontpath=${datadir}/fonts \
|
||||
--without-libidn --disable-fontconfig \
|
||||
--disable-freetype --disable-cups"
|
||||
|
||||
# This has been fixed upstream but for now we need to subvert the check for time.h
|
||||
# http://bugs.ghostscript.com/show_bug.cgi?id=692443
|
||||
# http://bugs.ghostscript.com/show_bug.cgi?id=692426
|
||||
CFLAGS += "-DHAVE_SYS_TIME_H=1"
|
||||
BUILD_CFLAGS += "-DHAVE_SYS_TIME_H=1"
|
||||
|
||||
inherit autotools-brokensep
|
||||
|
||||
do_configure_prepend () {
|
||||
mkdir -p obj
|
||||
mkdir -p soobj
|
||||
if [ -e ${WORKDIR}/objarch.h ]; then
|
||||
cp ${WORKDIR}/objarch.h obj/arch.h
|
||||
fi
|
||||
}
|
||||
|
||||
do_configure_append () {
|
||||
# copy tools from the native ghostscript build
|
||||
if [ "${PN}" != "ghostscript-native" ]; then
|
||||
mkdir -p obj/aux soobj
|
||||
for i in genarch genconf mkromfs echogs gendev genht; do
|
||||
cp ${STAGING_BINDIR_NATIVE}/ghostscript-${PV}/$i obj/aux/$i
|
||||
done
|
||||
fi
|
||||
}
|
||||
|
||||
do_install_append () {
|
||||
mkdir -p ${D}${datadir}/ghostscript/${PV}/
|
||||
cp -r Resource ${D}${datadir}/ghostscript/${PV}/
|
||||
cp -r iccprofiles ${D}${datadir}/ghostscript/${PV}/
|
||||
}
|
||||
|
||||
do_compile_class-native () {
|
||||
mkdir -p obj
|
||||
for i in genarch genconf mkromfs echogs gendev genht; do
|
||||
oe_runmake obj/aux/$i
|
||||
done
|
||||
}
|
||||
|
||||
do_install_class-native () {
|
||||
install -d ${D}${bindir}/ghostscript-${PV}
|
||||
for i in genarch genconf mkromfs echogs gendev genht; do
|
||||
install -m 755 obj/aux/$i ${D}${bindir}/ghostscript-${PV}/$i
|
||||
done
|
||||
}
|
||||
|
||||
BBCLASSEXTEND = "native"
|
||||
|
||||
# Ghostscript install tool 'instcopy' tries to remove already created
|
||||
# directories during install and parallel make causes problems.
|
||||
PARALLEL_MAKEINST=""
|
||||
|
||||
Reference in New Issue
Block a user