python3-pygobject: upgrade 3.48.2 -> 3.50.0

Add RDEPENDS on asyncio as per changelog.

Changelog:
===========
* tests: Fix event test errors when GTK is not installed :mr:'347'
* Rename master branch to main
* Drop support for Python 3.8 :mr:'300'
* Add Override for Gio.DataInputStream :mr:'293'
* Treat GParamSpec as any other fundamental type :mr:'268'
* override connection.register_object to prevent an invocation object from
  leaking :mr:'219'
* Various PyPy related fixes :mr:'299'
* bind_property: Accept keyword arguments :mr:'309'
* Various documentation improvements :mr:'342' :mr:'343' :mr:'338'
  :mr:'336' :mr:'335' :mr:'328' :mr:'329' :mr:'330' :mr:'325' :mr:'322' :mr:'312'
* Python2 / GTK2 cleanups :mr:'338' :mr:'331'
* asyncio integration with support to await Gio async functions :mr:'189'
* meson: move from .egg-info to .dist-info/METADATA :mr:'306'
* build: fixes for building with gobject-introspection 1.81 :mr:'344'

(From OE-Core rev: 2f599132609cef9843b48262c2e1eae1a289f460)

Signed-off-by: Ross Burton <ross.burton@arm.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

meta/recipes-devtools/python/python3-pygobject_3.50.0.bb

@@ -0,0 +1,40 @@
+SUMMARY = "Python GObject bindings"
+HOMEPAGE = "https://gitlab.gnome.org/GNOME/pygobject"
+DESCRIPTION = "PyGObject is a Python package which provides bindings for GObject based libraries such as GTK, GStreamer, WebKitGTK, GLib, GIO and many more."
+SECTION = "devel/python"
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a916467b91076e631dd8edb7424769c7"
+
+GIR_MESON_OPTION = ""
+
+inherit gnomebase setuptools3-base gobject-introspection upstream-version-is-even
+
+python() {
+    if d.getVar('CLASSOVERRIDE') == "class-target" and not bb.utils.to_boolean(d.getVar("GI_DATA_ENABLED")):
+        raise bb.parse.SkipRecipe("GI not available")
+}
+
+DEPENDS += "python3 glib-2.0"
+
+SRCNAME="pygobject"
+
+SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/${SRCNAME}/${@gnome_verdir("${PV}")}/${SRCNAME}-${PV}.tar.xz"
+SRC_URI[sha256sum] = "8d836e75b5a881d457ee1622cae4a32bcdba28a0ba562193adb3bbb472472212"
+
+S = "${WORKDIR}/${SRCNAME}-${PV}"
+
+PACKAGECONFIG ??= "${@bb.utils.contains_any('DISTRO_FEATURES', [ 'directfb', 'wayland', 'x11' ], 'cairo', '', d)}"
+
+RDEPENDS:${PN} += " \
+    python3-asyncio \
+    python3-io \
+    python3-pkgutil \
+"
+
+# python3-pycairo is checked on configuration -> DEPENDS
+# we don't link against python3-pycairo -> RDEPENDS
+PACKAGECONFIG[cairo] = "-Dpycairo=enabled,-Dpycairo=disabled, cairo python3-pycairo, python3-pycairo"
+PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,"
+
+BBCLASSEXTEND = "native"
+PACKAGECONFIG:class-native = ""