python3-cffi: upgrade 1.16.0 -> 1.17.0

https://github.com/python-cffi/cffi/compare/v1.17.0...v1.16.0

https://cffi.readthedocs.io/en/latest/whatsnew.html#v1-17

v1.17
  * In API mode, when you get a function from a C library by writing
  fn = lib.myfunc, you get an object of a special type for performance
  reasons, instead of a <cdata ‘C-function-type’>. Before version 1.17 you
  could only call such objects. You could write ffi.addressof(lib, “myfunc”)
  in order to get a real <cdata> object, based on the idea that in these cases
  in C you’d usually write &myfunc instead of myfunc. In version 1.17, the
  special object lib.myfunc can now be passed in many places where CFFI expects
  a regular <cdata> object. For example, you can now pass it as a callback to a
  C function call, or write it inside a C structure field of the correct
  pointer-to-function type, or use ffi.cast() or ffi.typeof() on it.

(From OE-Core rev: 375e59bfb4d610f89dd04c93f912d5847a5fac4f)

Signed-off-by: Tim Orling <tim.orling@konsulko.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

meta/recipes-devtools/python/python3-cffi_1.17.0.bb

@@ -0,0 +1,38 @@
+SUMMARY = "Foreign Function Interface for Python calling C code"
+HOMEPAGE = "http://cffi.readthedocs.org/"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=5677e2fdbf7cdda61d6dd2b57df547bf"
+DEPENDS += "libffi python3-pycparser"
+
+SRC_URI[sha256sum] = "f3157624b7558b914cb039fd1af735e5e8049a87c817cc215109ad1c8779df76"
+
+SRC_URI += "file://run-ptest"
+
+inherit pypi python_setuptools_build_meta ptest
+
+do_install_ptest() {
+    cp -r ${S}/testing ${D}${PTEST_PATH}
+    # These two files from the source tree are needed by the tests
+    install -D -m644 ${S}/src/c/parse_c_type.c ${D}${PTEST_PATH}/src/c/parse_c_type.c
+    install -D -m644 ${S}/src/cffi/parse_c_type.h ${D}${PTEST_PATH}/src/cffi/parse_c_type.h
+}
+
+RDEPENDS:${PN} = " \
+    python3-ctypes \
+    python3-io \
+    python3-pycparser \
+    python3-setuptools \
+    python3-shell \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    python3-pytest \
+    python3-unittest-automake-output \
+    python3-dev \
+    gcc-symlinks \
+    g++-symlinks \
+"
+
+INSANE_SKIP:${PN}-ptest = "dev-deps"
+
+BBCLASSEXTEND = "native nativesdk"