python3-maturin: upgrade 1.8.3 -> 1.8.6

* Add comment about riscv32gc ioctl codes patch, it is needed until libc
  version is 0.2.172 or greater in Cargo.lock.

Comparing changes since 1.8.3:
https://github.com/PyO3/maturin/compare/v1.8.3...v1.8.6

Changelog:

1.8.6
* Print a message when overriding platform tag from _PYTHON_HOST_PLATFORM
  in #2594
* Use the current python interpreter's version when the abi3 feature is set
  with no explicit version in #2597

1.8.5
* Fix release CI build

1.8.4
* Install a Rust toolchain into a temporary directory when building maturin
  itself or a package and a Rust toolchain is missing. Set
  MATURIN_NO_INSTALL_RUST to disable this behavior. #2421
* Fix broken maturin develop with latest uv in #2584
* Add PYO3_PYTHON env var support in #2534
* Sort RECORD file in wheel archives to make them deterministic in #2550
* Publish wheel for loongarch64 in #2548
* Add --compression-level option to build command in #2572

(From OE-Core rev: 92387900825dc6570c9bb43ca4b5a7d44f821f5c)

Signed-off-by: Tim Orling <tim.orling@konsulko.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

meta/recipes-devtools/python/python3-maturin_1.8.6.bb

@@ -0,0 +1,44 @@
+SUMMARY = "Build and publish crates with pyo3, rust-cpython, cffi bindings and rust binaries as python packages"
+HOMEPAGE = "https://github.com/pyo3/maturin"
+SECTION = "devel/python"
+LICENSE = "MIT | Apache-2.0"
+LIC_FILES_CHKSUM = "file://license-apache;md5=1836efb2eb779966696f473ee8540542 \
+                    file://license-mit;md5=85fd3b67069cff784d98ebfc7d5c0797"
+
+# This is needed until Cargo.lock has libc-0.2.172+
+SRC_URI += "file://0001-Define-more-ioctl-codes-on-riscv32gc-unknown-linux-g.patch;patchdir=${CARGO_VENDORING_DIRECTORY}/libc-0.2.167"
+SRC_URI[sha256sum] = "0e0dc2e0bfaa2e1bd238e0236cf8a2b7e2250ccaa29c1aa8d0e61fa664b0289d"
+
+S = "${WORKDIR}/maturin-${PV}"
+
+CFLAGS += "-ffile-prefix-map=${CARGO_HOME}=${TARGET_DBGSRC_DIR}/cargo_home"
+
+DEPENDS += "\
+    python3-setuptools-rust-native \
+    python3-semantic-version-native \
+    python3-setuptools-rust \
+"
+
+require ${BPN}-crates.inc
+
+inherit pypi cargo-update-recipe-crates python_pyo3 python_setuptools_build_meta
+
+do_configure() {
+    python_pyo3_do_configure
+    cargo_common_do_configure
+    python_pep517_do_configure
+}
+
+RDEPENDS:${PN} += "\
+    cargo \
+    python3-json \
+    rust \
+"
+
+RRECOMMENDS:${PN} += "\
+    python3-ensurepip \
+    python3-pip \
+    python3-venv \
+"
+
+BBCLASSEXTEND = "native nativesdk"