python3-pygobject: update 3.46.0 -> 3.48.1

Changelog:
===========
* Fix installation with pip failing in some environments with
  ModuleNotFoundError in g-ir-scanner :issue:'622' :mr:'302'
* test: fix some tests on macOS :mr:'296'
* docs: some dark mode fixes :mr:'291'
* Drop setuptools in favor of meson-python :mr:'248' :mr:'253' :mr:'254' :mr:'255' :mr:'276'
* Fundamental type support :mr:'250'
* Fundamental type support for GValues :mr:'264'
* pygi-convert.sh: migrate FILE_CHOOSER_CONFIRMATION_* :mr:'266'
* gimodule, cairo: Use multi-phase initialization as per PEP-489 :mr:'271'
* Deprecate classes in gi.option module :mr:'272'
* Deprecate pygtkcompat :mr:'278'
* Add support for (optional) nullable GErrors :mr:'259'
* Fix CssProvider not valid in GTK2 :mr:'284'
* Fix double free if array item cannot be marshalled to Python :mr:'280'
* Raise exception if a callback property is encountered :mr:'269'
* build: Fix pycairo detection "script" for Windows :mr:'267'
* Replace deprecated ''pkgutil.find_loader'' call :mr:'252'
* Avoid segfault on property access for incompletely initialized objects :mr:'260'
* pygenum: When getting a member instance, use correct key for the lookup :mr:'262'

(From OE-Core rev: 49ee7fff74464ca2838c609f2b6f4d1b8e09e8bc)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

meta/recipes-devtools/python/python3-pygobject_3.48.1.bb

@@ -0,0 +1,39 @@
+SUMMARY = "Python GObject bindings"
+HOMEPAGE = "https://gitlab.gnome.org/GNOME/pygobject"
+DESCRIPTION = "PyGObject is a Python package which provides bindings for GObject based libraries such as GTK, GStreamer, WebKitGTK, GLib, GIO and many more."
+SECTION = "devel/python"
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a916467b91076e631dd8edb7424769c7"
+
+GIR_MESON_OPTION = ""
+
+inherit gnomebase setuptools3-base gobject-introspection upstream-version-is-even
+
+python() {
+    if d.getVar('CLASSOVERRIDE') == "class-target" and not bb.utils.to_boolean(d.getVar("GI_DATA_ENABLED")):
+        raise bb.parse.SkipRecipe("GI not available")
+}
+
+DEPENDS += "python3 glib-2.0"
+
+SRCNAME="pygobject"
+
+SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/${SRCNAME}/${@gnome_verdir("${PV}")}/${SRCNAME}-${PV}.tar.xz"
+SRC_URI[sha256sum] = "3a0a2c0c0f25931b5840649c54834b9e58a63148d37fa9f6308887b7027e15c2"
+
+S = "${WORKDIR}/${SRCNAME}-${PV}"
+
+PACKAGECONFIG ??= "${@bb.utils.contains_any('DISTRO_FEATURES', [ 'directfb', 'wayland', 'x11' ], 'cairo', '', d)}"
+
+RDEPENDS:${PN} += " \
+    python3-io \
+    python3-pkgutil \
+"
+
+# python3-pycairo is checked on configuration -> DEPENDS
+# we don't link against python3-pycairo -> RDEPENDS
+PACKAGECONFIG[cairo] = "-Dpycairo=enabled,-Dpycairo=disabled, cairo python3-pycairo, python3-pycairo"
+PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,"
+
+BBCLASSEXTEND = "native"
+PACKAGECONFIG:class-native = ""