trace-cmd: Update to version 2.5.3

Updating adds new features including the very useful 'profile' option.

Changes include:

 - Remove addldflags.patch (already upstream in the new version).

 - Remove make-docs-optional.patch (docs are built in a separate target
   in the new version).

 - Update SRC_URI, SRCREV, PR, and PV in the .inc file and don't
   override them in the recipe.

 - Fix a typo in LIC_FILES_CHECKSUM so 'endline' is properly defined.

 - Drop PR.

(From OE-Core rev: 30eba39bd3b915477c584d8bebd194446497175e)

Signed-off-by: Ben Shelton <ben.shelton@ni.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

meta/recipes-kernel/trace-cmd/trace-cmd_git.bb

@@ -0,0 +1,35 @@
+SUMMARY = "User interface to Ftrace"
+LICENSE = "GPLv2 & LGPLv2.1"
+
+require trace-cmd.inc
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://trace-cmd.c;beginline=6;endline=8;md5=2c22c965a649ddd7973d7913c5634a5e \
+                    file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff \
+                    file://trace-input.c;beginline=5;endline=8;md5=3ec82f43bbe0cfb5951ff414ef4d44d0 \
+"
+
+EXTRA_OEMAKE = "\
+    'prefix=${prefix}' \
+    'bindir=${bindir}' \
+    'man_dir=${mandir}' \
+    'html_install=${datadir}/kernelshark/html' \
+    'img_install=${datadir}/kernelshark/html/images' \
+    \
+    'bindir_relative=${@oe.path.relative(prefix, bindir)}' \
+    'libdir=${@oe.path.relative(prefix, libdir)}' \
+    \
+    NO_PYTHON=1 \
+"
+
+FILES_${PN}-dbg += "${libdir}/trace-cmd/plugins/.debug"
+
+do_compile_prepend() {
+    # Make sure the recompile is OK
+    rm -f ${B}/.*.d
+}
+
+do_install() {
+        oe_runmake DESTDIR="${D}" install
+}
+