python3-maturin: upgrade 1.7.0 -> 1.7.1

Changelog
=========
- Update clap_complete_command to v0.6.1
- Fix platform tags when cross-compiling universal2
- Fix Typo in Migration Guide
- Fix rust 1.80 clippy errors
- Don't check .gitignore files in parent directories
- Replace --skip-auditwheel with --auditwheel option
- Remove install_requires and setup_requires from setup.py
- Use modern stripping option
- Move project metadata from setup.py to pyproject.toml
- Update manylinux/musllinux policies to the latest main
- use just licenses as the license directory in a wheel
- Forward cargo package --list warnings
- Add current package context to source dist error
- Place source dist readmes next to Cargo.toml

(From OE-Core rev: 48e00b925648dc394bf3ba08324b333b44a5ec0b)

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

meta/recipes-devtools/python/python3-maturin_1.7.1.bb

@@ -0,0 +1,42 @@
+SUMMARY = "Build and publish crates with pyo3, rust-cpython, cffi bindings and rust binaries as python packages"
+HOMEPAGE = "https://github.com/pyo3/maturin"
+SECTION = "devel/python"
+LICENSE = "MIT | Apache-2.0"
+LIC_FILES_CHKSUM = "file://license-apache;md5=1836efb2eb779966696f473ee8540542 \
+                    file://license-mit;md5=85fd3b67069cff784d98ebfc7d5c0797"
+
+SRC_URI[sha256sum] = "147754cb3d81177ee12d9baf575d93549e76121dacd3544ad6a50ab718de2b9c"
+
+S = "${WORKDIR}/maturin-${PV}"
+
+CFLAGS += "-fdebug-prefix-map=${CARGO_HOME}=${TARGET_DBGSRC_DIR}/cargo_home"
+
+DEPENDS += "\
+    python3-setuptools-rust-native \
+    python3-semantic-version-native \
+    python3-setuptools-rust \
+"
+
+require ${BPN}-crates.inc
+
+inherit pypi cargo-update-recipe-crates python_pyo3 python_setuptools_build_meta
+
+do_configure() {
+    python_pyo3_do_configure
+    cargo_common_do_configure
+    python_pep517_do_configure
+}
+
+RDEPENDS:${PN} += "\
+    cargo \
+    python3-json \
+    rust \
+"
+
+RRECOMMENDS:${PN} += "\
+    python3-ensurepip \
+    python3-pip \
+    python3-venv \
+"
+
+BBCLASSEXTEND = "native nativesdk"