python3-cryptography: upgrade 42.0.5 -> 42.0.7

Also upgrade python3-cryptography-vectors Refresh python3-cryptography-crates.inc 42.0.7 - 2024-05-06 Restored Windows 7 compatibility for our pre-built wheels. Note that we do not test on Windows 7 and wheels for our next release will not support it. Microsoft no longer provides support for Windows 7 and users are encouraged to upgrade. 42.0.6 - 2024-05-04 Fixed compilation when using LibreSSL 3.9.1. https://cryptography.io/en/latest/changelog/#v42-0-7 https://cryptography.io/en/latest/changelog/#v42-0-6 https://github.com/pyca/cryptography/compare/42.0.5...42.0.7 (From OE-Core rev: e4b16965cea57f72554c2e71ec07091afeeec9d8) Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
2026-02-08 09:46:38 +01:00 · 2024-05-21 09:24:17 -07:00
parent d80224d83b
commit b31f7fd4ae
4 changed files with 8 additions and 11 deletions
--- a/meta/recipes-devtools/python/python3-cryptography_42.0.7.bb
+++ b/meta/recipes-devtools/python/python3-cryptography_42.0.7.bb
@@ -0,0 +1,67 @@
+SUMMARY = "Provides cryptographic recipes and primitives to python developers"
+HOMEPAGE = "https://cryptography.io/"
+SECTION = "devel/python"
+LICENSE = "Apache-2.0 | BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8c3617db4fb6fae01f1d253ab91511e4 \
+                    file://LICENSE.APACHE;md5=4e168cce331e5c827d4c2b68a6200e1b \
+                    file://LICENSE.BSD;md5=5ae30ba4123bc4f2fa49aa0b0dce887b \
+                   "
+LDSHARED += "-pthread"
+
+SRC_URI[sha256sum] = "ecbfbc00bf55888edda9868a4cf927205de8499e7fabe6c050322298382953f2"
+
+SRC_URI += "file://0001-pyproject.toml-remove-benchmark-disable-option.patch \
+            file://check-memfree.py \
+            file://run-ptest \
+           "
+
+require ${BPN}-crates.inc
+
+inherit pypi python_setuptools3_rust cargo-update-recipe-crates pkgconfig
+
+DEPENDS += " \
+    python3-cffi-native \
+"
+
+RDEPENDS:${PN} += " \
+    python3-cffi \
+"
+
+RDEPENDS:${PN}:append:class-target = " \
+    python3-numbers \
+    python3-threading \
+"
+
+RDEPENDS:${PN}-ptest += " \
+    python3-bcrypt \
+    python3-cryptography-vectors (= ${PV}) \
+    python3-hypothesis \
+    python3-iso8601 \
+    python3-mmap \
+    python3-pretend \
+    python3-psutil \
+    python3-pytest \
+    python3-unittest-automake-output \
+    python3-pytest-subtests \
+    python3-pytz \
+"
+
+inherit ptest
+
+do_install_ptest() {
+    install -D ${UNPACKDIR}/check-memfree.py ${D}${PTEST_PATH}/
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+    # remove test_x509.py as it needs benchmark and we don't
+    # want to introduce the benchmark dependency
+    rm -rf ${D}${PTEST_PATH}/tests/bench/test_x509.py
+    install -d ${D}${PTEST_PATH}/tests/hazmat
+    cp -rf ${S}/tests/hazmat/* ${D}${PTEST_PATH}/tests/hazmat/
+    cp -r ${S}/pyproject.toml ${D}${PTEST_PATH}/
+}
+
+FILES:${PN}-dbg += " \
+    ${PYTHON_SITEPACKAGES_DIR}/${SRCNAME}/hazmat/bindings/.debug \
+"
+
+BBCLASSEXTEND = "native nativesdk"