mirror of
https://git.yoctoproject.org/poky
synced 2026-09-13 00:49:33 +02:00
libxml2: update to 2.9.10
(From OE-Core rev: de72e0440bc36fab09a7e3c13d3967c97dcda66b) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
This commit is contained in:
Alexander Kanavin
committed by
Richard Purdie
Richard Purdie
parent
d80f1a2c09
commit
d62895e112
110
meta/recipes-core/libxml/libxml2_2.9.10.bb
Normal file
110
meta/recipes-core/libxml/libxml2_2.9.10.bb
Normal file
@@ -0,0 +1,110 @@
|
||||
SUMMARY = "XML C Parser Library and Toolkit"
|
||||
DESCRIPTION = "The XML Parser Library allows for manipulation of XML files. Libxml2 exports Push and Pull type parser interfaces for both XML and HTML. It can do DTD validation at parse time, on a parsed document instance or with an arbitrary DTD. Libxml2 includes complete XPath, XPointer and Xinclude implementations. It also has a SAX like interface, which is designed to be compatible with Expat."
|
||||
HOMEPAGE = "http://www.xmlsoft.org/"
|
||||
BUGTRACKER = "http://bugzilla.gnome.org/buglist.cgi?product=libxml2"
|
||||
SECTION = "libs"
|
||||
LICENSE = "MIT"
|
||||
LIC_FILES_CHKSUM = "file://Copyright;md5=2044417e2e5006b65a8b9067b683fcf1 \
|
||||
file://hash.c;beginline=6;endline=15;md5=96f7296605eae807670fb08947829969 \
|
||||
file://list.c;beginline=4;endline=13;md5=cdbfa3dee51c099edb04e39f762ee907 \
|
||||
file://trio.c;beginline=5;endline=14;md5=6c025753c86d958722ec76e94cae932e"
|
||||
|
||||
DEPENDS = "zlib virtual/libiconv"
|
||||
|
||||
SRC_URI = "http://www.xmlsoft.org/sources/libxml2-${PV}.tar.gz;name=libtar \
|
||||
http://www.w3.org/XML/Test/xmlts20080827.tar.gz;subdir=${BP};name=testtar \
|
||||
file://libxml-64bit.patch \
|
||||
file://runtest.patch \
|
||||
file://run-ptest \
|
||||
file://python-sitepackages-dir.patch \
|
||||
file://libxml-m4-use-pkgconfig.patch \
|
||||
file://0001-Make-ptest-run-the-python-tests-if-python-is-enabled.patch \
|
||||
file://fix-execution-of-ptests.patch \
|
||||
"
|
||||
|
||||
SRC_URI[libtar.md5sum] = "10942a1dc23137a8aa07f0639cbfece5"
|
||||
SRC_URI[libtar.sha256sum] = "aafee193ffb8fe0c82d4afef6ef91972cbaf5feea100edc2f262750611b4be1f"
|
||||
SRC_URI[testtar.md5sum] = "ae3d1ebe000a3972afa104ca7f0e1b4a"
|
||||
SRC_URI[testtar.sha256sum] = "96151685cec997e1f9f3387e3626d61e6284d4d6e66e0e440c209286c03e9cc7"
|
||||
|
||||
BINCONFIG = "${bindir}/xml2-config"
|
||||
|
||||
PACKAGECONFIG ??= "python \
|
||||
${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \
|
||||
"
|
||||
PACKAGECONFIG[python] = "--with-python=${PYTHON},--without-python,python3"
|
||||
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
||||
|
||||
inherit autotools pkgconfig binconfig-disabled ptest features_check
|
||||
|
||||
inherit ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python3native', '', d)}
|
||||
|
||||
RDEPENDS_${PN}-ptest += "make ${@bb.utils.contains('PACKAGECONFIG', 'python', 'libgcc python3-core python3-logging python3-shell python3-stringold python3-threading python3-unittest ${PN}-python', '', d)}"
|
||||
|
||||
RDEPENDS_${PN}-python += "${@bb.utils.contains('PACKAGECONFIG', 'python', 'python3-core', '', d)}"
|
||||
|
||||
RDEPENDS_${PN}-ptest_append_libc-glibc = " glibc-gconv-ebcdic-us \
|
||||
glibc-gconv-ibm1141 \
|
||||
glibc-gconv-iso8859-5 \
|
||||
glibc-gconv-euc-jp \
|
||||
locale-base-en-us \
|
||||
"
|
||||
|
||||
export PYTHON_SITE_PACKAGES="${PYTHON_SITEPACKAGES_DIR}"
|
||||
|
||||
# WARNING: zlib is required for RPM use
|
||||
EXTRA_OECONF = "--without-debug --without-legacy --with-catalog --without-docbook --with-c14n --without-lzma --with-fexceptions"
|
||||
EXTRA_OECONF_class-native = "--without-legacy --without-docbook --with-c14n --without-lzma --with-zlib"
|
||||
EXTRA_OECONF_class-nativesdk = "--without-legacy --without-docbook --with-c14n --without-lzma --with-zlib"
|
||||
EXTRA_OECONF_linuxstdbase = "--with-debug --with-legacy --with-docbook --with-c14n --without-lzma --with-zlib"
|
||||
|
||||
python populate_packages_prepend () {
|
||||
# autonamer would call this libxml2-2, but we don't want that
|
||||
if d.getVar('DEBIAN_NAMES'):
|
||||
d.setVar('PKG_libxml2', '${MLPREFIX}libxml2')
|
||||
}
|
||||
|
||||
PACKAGE_BEFORE_PN += "${PN}-utils"
|
||||
PACKAGES += "${PN}-python"
|
||||
|
||||
FILES_${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/*.a"
|
||||
FILES_${PN}-dev += "${libdir}/xml2Conf.sh ${libdir}/cmake/*"
|
||||
FILES_${PN}-utils = "${bindir}/*"
|
||||
FILES_${PN}-python = "${PYTHON_SITEPACKAGES_DIR}"
|
||||
|
||||
do_configure_prepend () {
|
||||
# executables take longer to package: these should not be executable
|
||||
find ${S}/xmlconf/ -type f -exec chmod -x {} \+
|
||||
}
|
||||
|
||||
do_compile_ptest() {
|
||||
oe_runmake check-am
|
||||
}
|
||||
|
||||
do_install_ptest () {
|
||||
cp -r ${S}/xmlconf ${D}${PTEST_PATH}
|
||||
if [ "${@bb.utils.filter('PACKAGECONFIG', 'python', d)}" ]; then
|
||||
sed -i -e 's|^\(PYTHON = \).*|\1${USRBINPATH}/${PYTHON_PN}|' \
|
||||
${D}${PTEST_PATH}/python/tests/Makefile
|
||||
grep -lrZ '#!/usr/bin/python' ${D}${PTEST_PATH}/python |
|
||||
xargs -0 sed -i -e 's|/usr/bin/python|${USRBINPATH}/${PYTHON_PN}|'
|
||||
fi
|
||||
#Remove build host references from various Makefiles
|
||||
find "${D}${PTEST_PATH}" -name Makefile -type f -exec \
|
||||
sed -i \
|
||||
-e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
|
||||
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
||||
-e 's:${HOSTTOOLS_DIR}/::g' \
|
||||
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
||||
-e 's:${RECIPE_SYSROOT}::g' \
|
||||
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
|
||||
-e '/^RELDATE/d' \
|
||||
{} +
|
||||
}
|
||||
|
||||
do_install_append_class-native () {
|
||||
# Docs are not needed in the native case
|
||||
rm ${D}${datadir}/gtk-doc -rf
|
||||
}
|
||||
|
||||
BBCLASSEXTEND = "native nativesdk"
|
||||
Reference in New Issue
Block a user