linux-libc-headers: upgrade from 2.6.33 to 2.6.34

added a new patch to fix glibc build issue on powerpc
  ppc_glibc_build_fix.patch

Added attribution to the hayes-gone.patch.

And updated the metadata variables like LICENSE & LIC_CHKSUM_FILES

And removing all the older recipes and related files

Change the linux-libc-header version inpoky-default.inc

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>

meta/packages/linux-libc-headers/linux-libc-headers_2.6.34.bb

@@ -0,0 +1,48 @@
+require linux-libc-headers.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"
+PR = "r0"
+
+SRC_URI += "file://hayes-gone.patch \
+           file://ppc_glibc_build_fix.patch"
+
+S = "${WORKDIR}/linux-${PV}"
+
+set_arch() {
+	case ${TARGET_ARCH} in
+		alpha*)   ARCH=alpha ;;
+		arm*)     ARCH=arm ;;
+		cris*)    ARCH=cris ;;
+		hppa*)    ARCH=parisc ;;
+		i*86*)    ARCH=i386 ;;
+		ia64*)    ARCH=ia64 ;;
+		mips*)    ARCH=mips ;;
+		m68k*)    ARCH=m68k ;;
+		powerpc*) ARCH=powerpc ;;
+		s390*)    ARCH=s390 ;;
+		sh*)      ARCH=sh ;;
+		sparc64*) ARCH=sparc64 ;;
+		sparc*)   ARCH=sparc ;;
+		x86_64*)  ARCH=x86_64 ;;
+		avr32*)   ARCH=avr32 ;;
+		bfin*)    ARCH=blackfin ;;
+	esac
+}
+
+do_configure() {
+	set_arch
+	oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_compile () {
+}
+
+do_install() {
+	set_arch
+	oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+	# Kernel should not be exporting this header
+	rm -f ${D}${exec_prefix}/include/scsi/scsi.h
+}
+
+BBCLASSEXTEND = "nativesdk"