mirror of
https://git.yoctoproject.org/poky
synced 2026-09-18 15:49:32 +02:00
a691562e5d
The autoconf macros detect the presence of -ldbm or -lndbm on the host system and add the library to link against, for now good reason I can explain. This patch makes the build behave determinstically whether they're present or not. Other than the extra linkage, there doesn't appear to be any other change in behaviour from these options and they look like dead code. The extra linkage can cause problems where sstate is used on a machine where the extra librbary isn't present causing build failures. (From OE-Core rev: f609bf5525450bfdb8e0864d44c41cce7f9319c9) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
36 lines
1.1 KiB
BlitzBasic
36 lines
1.1 KiB
BlitzBasic
DESCRIPTION = "GNU dbm is a set of database routines that use extensible hashing."
|
|
HOMEPAGE = "http://www.gnu.org/software/gdbm/"
|
|
SECTION = "libs"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=241da1b9fe42e642cbb2c24d5e0c4d24"
|
|
|
|
PR = "r3"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/gdbm/gdbm-${PV}.tar.gz"
|
|
|
|
SRC_URI[md5sum] = "88770493c2559dc80b561293e39d3570"
|
|
SRC_URI[sha256sum] = "23f8134c5b94bbfb06d756a6b78f074fba6e6028cf2fe01341d40b26db773441"
|
|
|
|
inherit autotools gettext lib_package
|
|
|
|
# Needed for dbm python module
|
|
EXTRA_OECONF = "-enable-libgdbm-compat"
|
|
|
|
# Stop presence of dbm/nbdm on the host contaminating builds
|
|
CACHED_CONFIGUREVARS += "ac_cv_lib_ndbm_main=no ac_cv_lib_dbm_main=no"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
do_install_append () {
|
|
# Create a symlink to ndbm.h and gdbm.h in include/gdbm to let other packages to find
|
|
# these headers
|
|
install -d ${D}${includedir}/gdbm
|
|
ln -sf ../ndbm.h ${D}/${includedir}/gdbm/ndbm.h
|
|
ln -sf ../gdbm.h ${D}/${includedir}/gdbm/gdbm.h
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-compat \
|
|
"
|
|
FILES_${PN}-compat = "${libdir}/libgdbm_compat${SOLIBS} \
|
|
"
|