mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
b2bd31b9cc
Do not tweak a file that is no longer installed. Ruby 3.0.3 includes security fixes. CVE-2021-41817: Regular Expression Denial of Service Vulnerability of Date Parsing Methods CVE-2021-41816: Buffer Overrun in CGI.escape_html CVE-2021-41819: Cookie Prefix Spoofing in CGI::Cookie.parse Ruby 3.0.2 release includes security fixes. CVE-2021-31810: Trusting FTP PASV responses vulnerability in Net::FTP CVE-2021-32066: A StartTLS stripping vulnerability in Net::IMAP CVE-2021-31799: A command injection vulnerability in RDoc (From OE-Core rev: edb6df08cb47a39918d28c709675d995c9e10031) Signed-off-by: Lee Chee Yang <chee.yang.lee@intel.com> Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
101 lines
3.3 KiB
BlitzBasic
101 lines
3.3 KiB
BlitzBasic
require ruby.inc
|
|
|
|
DEPENDS_append_libc-musl = " libucontext"
|
|
|
|
SRC_URI += " \
|
|
file://remove_has_include_macros.patch \
|
|
file://run-ptest \
|
|
file://0001-template-Makefile.in-do-not-write-host-cross-cc-item.patch \
|
|
file://0003-rdoc-build-reproducible-documentation.patch \
|
|
file://0004-lib-mkmf.rb-sort-list-of-object-files-in-generated-M.patch \
|
|
file://0005-Mark-Gemspec-reproducible-change-fixing-784225-too.patch \
|
|
file://0006-Make-gemspecs-reproducible.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "3586861cb2df56970287f0fd83f274bd92058872d830d15570b36def7f1a92ac"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG += "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
|
|
|
|
PACKAGECONFIG[valgrind] = "--with-valgrind=yes, --with-valgrind=no, valgrind"
|
|
PACKAGECONFIG[gmp] = "--with-gmp=yes, --with-gmp=no, gmp"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6,"
|
|
|
|
EXTRA_OECONF = "\
|
|
--disable-versioned-paths \
|
|
--disable-rpath \
|
|
--disable-dtrace \
|
|
--enable-shared \
|
|
--enable-load-relative \
|
|
--with-pkg-config=pkg-config \
|
|
"
|
|
|
|
EXTRA_OECONF_append_libc-musl = "\
|
|
LIBS='-lucontext' \
|
|
ac_cv_func_isnan=yes \
|
|
ac_cv_func_isinf=yes \
|
|
"
|
|
|
|
EXTRA_OECONF_append_libc-musl_riscv64 = "\
|
|
--with-coroutine=copy \
|
|
"
|
|
EXTRA_OECONF_append_libc-musl_riscv32 = "\
|
|
--with-coroutine=copy \
|
|
"
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
}
|
|
|
|
do_install_append_class-target () {
|
|
# Find out rbconfig.rb from .installed.list
|
|
rbconfig_rb=`grep rbconfig.rb ${B}/.installed.list`
|
|
# Remove build host directories
|
|
sed -i -e 's:--sysroot=${STAGING_DIR_TARGET}::g' \
|
|
-e s:'--with-libtool-sysroot=${STAGING_DIR_TARGET}'::g \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
-e 's:${HOSTTOOLS_DIR}/::g' \
|
|
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
|
-e 's:${RECIPE_SYSROOT}::g' \
|
|
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
|
|
${D}$rbconfig_rb
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp -rf ${S}/test ${D}${PTEST_PATH}/
|
|
|
|
install -D ${S}/tool/test/runner.rb ${D}${PTEST_PATH}/tool/test/runner.rb
|
|
cp -r ${S}/tool/lib ${D}${PTEST_PATH}/tool/
|
|
mkdir -p ${D}${PTEST_PATH}/lib
|
|
cp -r ${S}/lib/did_you_mean ${S}/lib/rdoc ${D}${PTEST_PATH}/lib
|
|
|
|
# install test-binaries
|
|
find $(find ./.ext -path '*/-test-') -name '*.so' -print0 \
|
|
| tar --no-recursion --null -T - --no-same-owner --preserve-permissions -cf - \
|
|
| tar -C ${D}${libdir}/ruby/${SHRT_VER}.0/ --no-same-owner --preserve-permissions --strip-components=2 -xf -
|
|
# adjust path to not assume build directory layout
|
|
sed -e 's|File.expand_path(.*\.\./bin/erb[^)]*|File.expand_path("${bindir}/erb"|g' \
|
|
-i ${D}${PTEST_PATH}/test/erb/test_erb_command.rb
|
|
|
|
cp -r ${S}/include ${D}/${libdir}/ruby/
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-ri-docs ${PN}-rdoc"
|
|
|
|
SUMMARY_${PN}-ri-docs = "ri (Ruby Interactive) documentation for the Ruby standard library"
|
|
RDEPENDS_${PN}-ri-docs = "${PN}"
|
|
FILES_${PN}-ri-docs += "${datadir}/ri"
|
|
|
|
SUMMARY_${PN}-rdoc = "RDoc documentation generator from Ruby source"
|
|
RDEPENDS_${PN}-rdoc = "${PN}"
|
|
FILES_${PN}-rdoc += "${libdir}/ruby/*/rdoc ${bindir}/rdoc"
|
|
|
|
FILES_${PN} += "${datadir}/rubygems"
|
|
|
|
FILES_${PN}-ptest_append_class-target = "\
|
|
${libdir}/ruby/include \
|
|
${libdir}/ruby/${SHRT_VER}.0/*/-test- \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native"
|