mirror of
https://git.yoctoproject.org/poky
synced 2026-09-15 15:49:32 +02:00
543567bb8a
Github has announced there will be no more git:// fetching from their servers: https://github.blog/2021-09-01-improving-git-protocol-security-github/#no-more-unauthenticated-git and they're about to start having brownout periods to encourage people to update. This runs the conversion script over OE-Core to update our urls to use https instead of git. (From OE-Core rev: 8b83eddda83327d25247bb9b61a049b0a8698a45) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit b37b61e9a1e448a34957db9ae39285d21352552e) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.3 KiB
BlitzBasic
43 lines
1.3 KiB
BlitzBasic
SUMMARY = "The SPIR-V Tools project provides an API and commands for \
|
|
processing SPIR-V modules"
|
|
DESCRIPTION = "The project includes an assembler, binary module parser, \
|
|
disassembler, validator, and optimizer for SPIR-V."
|
|
HOMEPAGE = "https://github.com/KhronosGroup/SPIRV-Tools"
|
|
SECTION = "graphics"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
SRCREV = "e198c6a785d388db68eb9166b43ac5e5208fd5cc"
|
|
SRC_URI = "git://github.com/KhronosGroup/SPIRV-Tools.git;branch=master;protocol=https \
|
|
file://0001-fix-strncpy-bound-error.patch \
|
|
"
|
|
UPSTREAM_CHECK_GITTAGREGEX = "^v(?P<pver>\d+(\.\d+)+)$"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake python3native
|
|
|
|
DEPENDS = "spirv-headers"
|
|
|
|
EXTRA_OECMAKE += "\
|
|
-DSPIRV-Headers_SOURCE_DIR=${STAGING_EXECPREFIXDIR} \
|
|
-DSPIRV_TOOLS_BUILD_STATIC=OFF \
|
|
-DBUILD_SHARED_LIBS=ON \
|
|
-DSPIRV_SKIP_TESTS=ON \
|
|
"
|
|
|
|
do_install:append:class-target() {
|
|
# reproducibility: remove build host path
|
|
sed -i ${D}${libdir}/cmake/SPIRV-Tools/SPIRV-ToolsTarget.cmake \
|
|
-e 's:${STAGING_DIR_HOST}::g'
|
|
}
|
|
|
|
# all the libraries are unversioned, so don't pack it on PN-dev
|
|
SOLIBS = ".so"
|
|
FILES_SOLIBSDEV = ""
|
|
|
|
PACKAGES =+ "${PN}-lesspipe"
|
|
FILES:${PN}-lesspipe = "${base_bindir}/spirv-lesspipe.sh"
|
|
RDEPENDS:${PN}-lesspipe += "${PN} bash"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|