mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
a1b3e8758e
Some of tests impose rlimit on it before running which wont be imposed when running as root user. Fixes src/regression/pthread_atfork-errno-clobber.c:23: (pid = fork()) == -1 failed: fork succeeded despite rlimit src/regression/pthread_atfork-errno-clobber.c:23: (pid = fork()) == -1 failed: fork succeeded despite rlimit FAIL src/regression/pthread_atfork-errno-clobber-static.exe [status 1] (From OE-Core rev: 585bf4b780a8ad60ba2b33cede4f0092ff61ddfc) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
1.4 KiB
BlitzBasic
58 lines
1.4 KiB
BlitzBasic
SUMMARY = "Musl libc unit tests"
|
|
HOMEPAGE = "https://wiki.musl-libc.org/libc-test.html"
|
|
DESCRIPTION = "libc-test is a collection of unit tests to measure the \
|
|
correctness and robustness of a C/POSIX standard library implementation. It is \
|
|
developed as part of the musl project."
|
|
SECTION = "tests"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=43ed1245085be90dc934288117d55a3b"
|
|
|
|
inherit ptest
|
|
|
|
SRCREV = "18e28496adee3d84fefdda6efcb9c5b8996a2398"
|
|
SRC_URI = " \
|
|
git://repo.or.cz/libc-test;branch=master;protocol=https \
|
|
file://run-ptest \
|
|
file://run-libc-ptests \
|
|
"
|
|
|
|
PV = "0+git"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# libc-test 'make' or 'make run' command is designed to build and run tests. It
|
|
# reports both build and test failures. The commands should be run on target.
|
|
do_compile() {
|
|
:
|
|
}
|
|
|
|
RDEPENDS:${PN} = " \
|
|
bash \
|
|
grep \
|
|
musl \
|
|
packagegroup-core-buildessential \
|
|
"
|
|
|
|
RDEPENDS:${PN}-ptest = " \
|
|
${PN} \
|
|
musl-staticdev \
|
|
sed \
|
|
"
|
|
|
|
install_path = "/opt/${PN}"
|
|
FILES:${PN} += "${install_path}/*"
|
|
|
|
do_install () {
|
|
install -d ${D}${install_path}/
|
|
cp ${S}/Makefile ${D}${install_path}
|
|
cp ${S}/config.mak.def ${D}${install_path}/config.mak
|
|
cp -r ${S}/src ${D}${install_path}
|
|
}
|
|
|
|
do_install_ptest_base:append() {
|
|
install -Dm 0755 ${WORKDIR}/run-libc-ptests ${D}${PTEST_PATH}/run-libc-ptests
|
|
}
|
|
|
|
COMPATIBLE_HOST = "null"
|
|
COMPATIBLE_HOST:libc-musl = "(.*)"
|