mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
b64374be63
Changelog: - Issue #67: restore support for reading kernel logs from '/proc/kmsg', regression introduced in v2.4.0, issue #48. - Issue #37: improved accuracy of the MARK timer, optional, default: 20 minutes. Generates log messages to files, which have had no activity within the MARK interval. Was off by up to 'interval / 2' minutes. It may now be off by up to '1 / 2' minutes, i.e.g, 30 seconds. - Issue #64: sub-second faking of kernel timestamps was always zero (From OE-Core rev: 64d7c4af897cb052b6951dce6519a705cf2ac0ac) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
1.7 KiB
BlitzBasic
57 lines
1.7 KiB
BlitzBasic
SUMMARY = "System Log Daemons"
|
|
DESCRIPTION = "The sysklogd package implements system log daemons: syslogd"
|
|
HOMEPAGE = "http://www.infodrom.org/projects/sysklogd/"
|
|
SECTION = "base"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5b4be4b2549338526758ef479c040943 \
|
|
file://src/syslogd.c;beginline=2;endline=15;md5=a880fecbc04503f071c494a9c0dd4f97 \
|
|
"
|
|
|
|
inherit update-rc.d update-alternatives systemd autotools
|
|
|
|
SRC_URI = "git://github.com/troglobit/sysklogd.git;branch=master;protocol=https \
|
|
file://sysklogd \
|
|
"
|
|
|
|
SRCREV = "3332c550f1a68393daec5d64cd81f3b7674c0af5"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OECONF = "--with-systemd=${systemd_system_unitdir} --without-logger"
|
|
|
|
do_install:append () {
|
|
install -d ${D}${sysconfdir}
|
|
install -m 644 ${S}/syslog.conf ${D}${sysconfdir}/syslog.conf
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 755 ${WORKDIR}/sysklogd ${D}${sysconfdir}/init.d/syslog
|
|
}
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "syslogd.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
INITSCRIPT_NAME = "syslog"
|
|
CONFFILES:${PN} = "${sysconfdir}/syslog.conf"
|
|
RCONFLICTS:${PN} = "rsyslog busybox-syslog syslog-ng"
|
|
|
|
FILES:${PN} += "${@bb.utils.contains('DISTRO_FEATURES','systemd','${exec_prefix}/lib/tmpfiles.d/sysklogd.conf', '', d)}"
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE:${PN}-doc = "syslogd.8"
|
|
ALTERNATIVE_LINK_NAME[syslogd.8] = "${mandir}/man8/syslogd.8"
|
|
|
|
pkg_prerm:${PN} () {
|
|
if test "x$D" = "x"; then
|
|
if test "$1" = "upgrade" -o "$1" = "remove"; then
|
|
/etc/init.d/syslog stop || :
|
|
fi
|
|
fi
|
|
}
|
|
|
|
python () {
|
|
if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
|
|
d.setVar("INHIBIT_UPDATERCD_BBCLASS", "1")
|
|
}
|