mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
398e77fc21
http://www.infradead.org/~tgr/libnl/ stops at 2014, the current official home page should be the github one. (From OE-Core rev: bc68ac83d158f3f0b2f67f89f541faecb094ea43) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit cfe7659e4c553c51d39322b378ac7fb2891c2dc6) Signed-off-by: Steve Sakoman <steve@sakoman.com>
65 lines
2.3 KiB
BlitzBasic
65 lines
2.3 KiB
BlitzBasic
SUMMARY = "A library for applications dealing with netlink sockets"
|
|
DESCRIPTION = "The libnl suite is a collection of libraries providing \
|
|
APIs to netlink protocol based Linux kernel interfaces. libnl is the core \
|
|
library implementing the fundamentals required to use the netlink protocol \
|
|
such as socket handling, message construction and parsing, and sending \
|
|
and receiving of data."
|
|
HOMEPAGE = "https://github.com/thom311/libnl"
|
|
SECTION = "libs/network"
|
|
|
|
PE = "1"
|
|
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
|
|
|
|
DEPENDS = "flex-native bison-native"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/${BPN}${@d.getVar('PV').replace('.','_')}/${BP}.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "aed507004d728a5cf11eab48ca4bf9e6e1874444e33939b9d3dfed25018ee9bb"
|
|
|
|
GITHUB_BASE_URI = "https://github.com/thom311/${BPN}/releases"
|
|
UPSTREAM_CHECK_REGEX = "releases/tag/libnl(?P<pver>.+)"
|
|
|
|
inherit autotools pkgconfig ptest github-releases
|
|
|
|
FILES:${PN} = "${libdir}/libnl-3.so.* \
|
|
${libdir}/libnl.so.* \
|
|
${sysconfdir}"
|
|
RREPLACES:${PN} = "libnl2"
|
|
RCONFLICTS:${PN} = "libnl2"
|
|
|
|
FILES:${PN}-dev += "${libdir}/libnl/cli/*/*.la"
|
|
FILES:${PN}-staticdev += "${libdir}/libnl/cli/*/*.a"
|
|
|
|
PACKAGES += "${PN}-cli ${PN}-genl ${PN}-idiag ${PN}-nf ${PN}-route ${PN}-xfrm"
|
|
FILES:${PN}-cli = "${libdir}/libnl-cli-3.so.* \
|
|
${libdir}/libnl/cli/*/*.so \
|
|
${bindir}/genl-ctrl-list \
|
|
${bindir}/idiag-socket-details \
|
|
${bindir}/nf-* \
|
|
${bindir}/nl-*"
|
|
FILES:${PN}-genl = "${libdir}/libnl-genl-3.so.* \
|
|
${libdir}/libnl-genl.so.*"
|
|
FILES:${PN}-idiag = "${libdir}/libnl-idiag-3.so.*"
|
|
FILES:${PN}-nf = "${libdir}/libnl-nf-3.so.*"
|
|
FILES:${PN}-route = "${libdir}/libnl-route-3.so.*"
|
|
FILES:${PN}-xfrm = "${libdir}/libnl-xfrm-3.so.*"
|
|
RREPLACES:${PN}-genl = "libnl-genl2"
|
|
RCONFLICTS:${PN}-genl = "libnl-genl2"
|
|
|
|
DEPENDS += "${@bb.utils.contains('PTEST_ENABLED', '1', 'libcheck', '', d)}"
|
|
RRECOMMENDS:${PN}-ptest += "kernel-module-dummy kernel-module-bonding"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake ./tests/check-all
|
|
}
|
|
|
|
do_install_ptest() {
|
|
./libtool install install ./tests/check-all ${D}${PTEST_PATH}/
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|