mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
6e409b5d19
Some recipes use setuptools3 but should be using a PEP517-compliant backend, be it the setuptools itself via python_setuptools_build_meta or an alternative backend such as flit/hatch/poetry. As we can't currently assume Python 3.11 on the build host we need to parse the pyproject.toml manually, but this should be sufficient for the limited parsing needed. This task emits a QA error if a build backend is set, and can be ignored by using INSANE_SKIP if needed. [ YOCTO #14736 ] (From OE-Core rev: a9d800f6cdfcedbe3de8366d935ee5f0c8557c06) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.6 KiB
Plaintext
53 lines
1.6 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
inherit setuptools3-base python_pep517
|
|
|
|
DEPENDS += "python3-setuptools-native python3-wheel-native"
|
|
|
|
SETUPTOOLS_BUILD_ARGS ?= ""
|
|
|
|
SETUPTOOLS_SETUP_PATH ?= "${S}"
|
|
|
|
python do_check_backend() {
|
|
import re
|
|
filename = d.expand("${SETUPTOOLS_SETUP_PATH}/pyproject.toml")
|
|
if os.path.exists(filename):
|
|
for line in open(filename):
|
|
match = re.match(r"build-backend\s*=\s*\W([\w.]+)\W", line)
|
|
if not match: continue
|
|
|
|
msg = f"inherits setuptools3 but has pyproject.toml with {match[1]}, use the correct class"
|
|
if "pep517-backend" not in (d.getVar("INSANE_SKIP") or "").split():
|
|
oe.qa.handle_error("pep517-backend", msg, d)
|
|
}
|
|
addtask check_backend after do_patch before do_configure
|
|
|
|
setuptools3_do_configure() {
|
|
:
|
|
}
|
|
|
|
setuptools3_do_compile() {
|
|
cd ${SETUPTOOLS_SETUP_PATH}
|
|
NO_FETCH_BUILD=1 \
|
|
STAGING_INCDIR=${STAGING_INCDIR} \
|
|
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
|
${STAGING_BINDIR_NATIVE}/python3-native/python3 setup.py \
|
|
bdist_wheel --verbose --dist-dir ${PEP517_WHEEL_PATH} ${SETUPTOOLS_BUILD_ARGS} || \
|
|
bbfatal_log "'python3 setup.py bdist_wheel ${SETUPTOOLS_BUILD_ARGS}' execution failed."
|
|
}
|
|
setuptools3_do_compile[vardepsexclude] = "MACHINE"
|
|
do_compile[cleandirs] += "${PEP517_WHEEL_PATH}"
|
|
|
|
# This could be removed in the future but some recipes in meta-oe still use it
|
|
setuptools3_do_install() {
|
|
python_pep517_do_install
|
|
}
|
|
|
|
EXPORT_FUNCTIONS do_configure do_compile do_install
|
|
|
|
export LDSHARED="${CCLD} -shared"
|