mirror of
https://git.yoctoproject.org/poky
synced 2026-02-21 17:09:42 +01:00
24d1560609
OE-Core commit 4a158b6ef125b555225472eefbe1ea226dc47c2c unintentionally removed the dependencies for util-linux-native on zlib-native and ncurses-native by getting append and virtclass-native overrides swapped around; later this was tidied up to remove the append (which did not change anything functionally). These libraries are required, so add them back in. (From OE-Core rev: 0038a030e605195284c98bc154f500a1343c252b) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.6 KiB
BlitzBasic
49 lines
1.6 KiB
BlitzBasic
MAJOR_VERSION = "2.21"
|
|
PR = "r5"
|
|
require util-linux.inc
|
|
|
|
# note that `lscpu' is under GPLv3+
|
|
LICENSE_util-linux-lscpu = "GPLv3+"
|
|
|
|
SRC_URI += "file://util-linux-ng-replace-siginterrupt.patch \
|
|
file://util-linux-ng-2.16-mount_lock_path.patch \
|
|
file://uclibc-__progname-conflict.patch \
|
|
file://fix_NL_TIME_FIRST_WEEKDAY.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "3c7a26963f3921c1e775a80330321870"
|
|
SRC_URI[sha256sum] = "2813ae6fe0449b60402e122c2baf97f26aa53e6e2dd05591c6cbcdf67ffdb6c6"
|
|
|
|
# Only lscpu part is gplv3; rest of the code is not,
|
|
# so take out the lscpu parts while running non-gplv3 build.
|
|
python () {
|
|
d.setVar("REMOVELSCPU", "no")
|
|
if (d.getVar("INCOMPATIBLE_LICENSE", True) or "").find("GPLv3") != -1:
|
|
# avoid GPLv3
|
|
d.setVar("REMOVELSCPU", "yes")
|
|
packages = (d.getVar("PACKAGES", False) or "").split()
|
|
if "util-linux-lscpu" in packages:
|
|
packages.remove("util-linux-lscpu")
|
|
d.setVar("PACKAGES", " ".join(packages))
|
|
|
|
src_uri = (d.getVar("SRC_URI", False) or "").split()
|
|
src_uri.append("file://remove-lscpu.patch")
|
|
d.setVar("SRC_URI", " ".join(src_uri))
|
|
}
|
|
|
|
do_remove_lscpu() {
|
|
if [ "x${REMOVELSCPU}" = "xyes" ]; then
|
|
rm -f sys-utils/lscpu.c sys-utils/lscpu.1
|
|
rm -rf tests/ts/lscpu tests/expected/lscpu
|
|
fi
|
|
}
|
|
|
|
addtask remove_lscpu before do_configure after do_patch
|
|
|
|
CACHED_CONFIGUREVARS += "scanf_cv_alloc_modifier=as"
|
|
EXTRA_OECONF_virtclass-native += "--disable-fallocate --disable-use-tty-group"
|
|
|
|
do_install_append () {
|
|
sed -i -e '1s,.*,#!${bindir}/env perl,' ${D}${bindir}/chkdupexe
|
|
}
|