mirror of
https://git.yoctoproject.org/poky
synced 2026-03-25 10:02:22 +01:00
0ea1ee305b
In some cases, we run into parallel build failures where BUILT_SOURCES
is skipped, as a result required header files are not generated and the
build fails with missing header errors like
../bison-3.5.2/lib/uniwidth/width.c:21:10: fatal error: uniwidth.h: No such file or directory
#include "uniwidth.h"
^~~~~~~~~~~~
compilation terminated.
BUILT_SOURCES should be built automatically with `make all` [1] therefore
ensure that make is invoked with `all` target
bison-native parallel build fails when -l<n> is passed globally from
build environment, errors like below due to race starts to show up
Therefore removes a previous load limit if set
[1] https://www.gnu.org/software/automake/manual/html_node/Built-Sources-Example.html#Built-Sources-Example
(From OE-Core rev: 1b8451aa4ba2b42b1eb1dc938fa3397d3434839a)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.6 KiB
BlitzBasic
45 lines
1.6 KiB
BlitzBasic
SUMMARY = "GNU Project parser generator (yacc replacement)"
|
|
DESCRIPTION = "Bison is a general-purpose parser generator that converts an annotated context-free grammar into \
|
|
an LALR(1) or GLR parser for that grammar. Bison is upward compatible with Yacc: all properly-written Yacc \
|
|
grammars ought to work with Bison with no change. Anyone familiar with Yacc should be able to use Bison with \
|
|
little trouble."
|
|
HOMEPAGE = "http://www.gnu.org/software/bison/"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
SECTION = "devel"
|
|
DEPENDS = "bison-native flex-native"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/bison/bison-${PV}.tar.xz \
|
|
file://dont-depend-on-help2man.patch.patch \
|
|
file://add-with-bisonlocaledir.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "2bf85b5f88a5f2fa8069aed2a2dfc3a9f8d15a97e59c713e3906e5fdd982a7c4"
|
|
|
|
# No point in hardcoding path to m4, just use PATH
|
|
EXTRA_OECONF += "M4=m4"
|
|
|
|
# Reset any loadavg set via environment, it breaks parallel build
|
|
# | ../bison-3.5.2/lib/uniwidth/width.c:21:10: fatal error: uniwidth.h: No such file or directory
|
|
# | #include "uniwidth.h"
|
|
# | ^~~~~~~~~~~~
|
|
EXTRA_OEMAKE_append = " -l"
|
|
|
|
inherit autotools gettext texinfo
|
|
|
|
# The automatic m4 path detection gets confused, so force the right value
|
|
acpaths = "-I ${S}/m4"
|
|
|
|
do_compile_prepend() {
|
|
for i in mfcalc calc++ rpcalc; do mkdir -p ${B}/examples/$i; done
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}/${bindir}/bison \
|
|
BISON_PKGDATADIR=${STAGING_DATADIR_NATIVE}/bison
|
|
}
|
|
do_install_append_class-nativesdk() {
|
|
create_wrapper ${D}/${bindir}/bison \
|
|
BISON_PKGDATADIR=${datadir}/bison
|
|
}
|
|
BBCLASSEXTEND = "native nativesdk"
|