mirror of
https://git.yoctoproject.org/poky
synced 2026-02-25 10:59:41 +01:00
f22d52f97e
Integrating the following commit(s) to linux-yocto/6.16:
1/1 [
Author: Trevor Woerner
Email: twoerner@gmail.com
Subject: defconfig: cleanup orphaned CONFIG_SCHED_DEBUG
Date: Tue, 16 Sep 2025 16:33:24 +0100
In commit b52173065e0a ("sched/debug: Remove CONFIG_SCHED_DEBUG") this
Kconfig option was removed since CONFIG_SCHED_DEBUG was made unconditional
by patches preceding it.
Signed-off-by: Trevor Woerner <twoerner@gmail.com>
Reviewed-by: Krzysztof Kozlowski <krzysztof.kozlowski@linaro.org>
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
]
(From OE-Core rev: 05c34570cfd43e38fcc70bba0a46dddb7ecb4e16)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
4.3 KiB
BlitzBasic
80 lines
4.3 KiB
BlitzBasic
KBRANCH ?= "v6.16/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# CVE exclusions
|
|
include recipes-kernel/linux/cve-exclusion.inc
|
|
include recipes-kernel/linux/cve-exclusion_6.16.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v6.16/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemumips ?= "v6.16/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v6.16/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v6.16/standard/base"
|
|
KBRANCH:qemux86 ?= "v6.16/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemuloongarch64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemumips64 ?= "v6.16/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "71e0898274de9dc6edff0f2d9d6fa213dae11272"
|
|
SRCREV_machine:qemuarm64 ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_machine:qemuloongarch64 ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_machine:qemumips ?= "c2ab3a7b951876e2fcbcae9bfa816f8484cc66cc"
|
|
SRCREV_machine:qemuppc ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_machine:qemuriscv64 ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_machine:qemuriscv32 ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_machine:qemux86 ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_machine:qemux86-64 ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_machine:qemumips64 ?= "14ae3e2469aa1e43fcb65a030d9c184bbec3585f"
|
|
SRCREV_machine ?= "946b80132b9ce459ba84f90d4b2f63eeace6014d"
|
|
SRCREV_meta ?= "5cfae705d58ce214867b7b25653efb03b613c6df"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "131e2001572ba68b6728bcba91c58647168d237f"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v6.16/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH};protocol=https \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.16;destsuffix=${KMETA};protocol=https"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "6.16.7"
|
|
|
|
PV = "${LINUX_VERSION}+git"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "arm/versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32|qemuloongarch64)$"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall = " cfg/virtio.scc features/drm-bochs/drm-bochs.scc cfg/net/mdio.scc"
|
|
KERNEL_FEATURES:append:qemux86 = " cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64 = " cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc features/nf_tables/nft_test.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc features/gpio/sim.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("KERNEL_DEBUG", "True", " features/reproducibility/reproducibility.scc features/debug/debug-btf.scc", "", d)}"
|
|
# libteam ptests from meta-oe needs it
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/net/team/team.scc", "", d)}"
|
|
# openl2tp tests from meta-networking needs it
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " cgl/cfg/net/l2tp.scc", "", d)}"
|
|
KERNEL_FEATURES:append:powerpc = " arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64 = " arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64le = " arch/powerpc/powerpc-debug.scc"
|
|
# Do not add debug info for riscv32, it fails during depmod
|
|
# ERROR: modpost: __ex_table+0x17a4 references non-executable section '.debug_loclists'
|
|
# Check again during next major version upgrade
|
|
KERNEL_FEATURES:remove:riscv32 = "features/debug/debug-kernel.scc"
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|