mirror of
https://git.yoctoproject.org/poky
synced 2026-02-21 08:59:41 +01:00
006da82356
Rust stable version updated to 1.88.0. https://blog.rust-lang.org/2025/06/26/Rust-1.88.0/ * Rebase existing patches with v1.88.0 * Exclude tidy and coverage-dump from OE self-tests due to test failures Although the build completes successfully, OE self-tests fail: tools/coverage-dump panics during test execution. tools/tidy fails due to a mismatched GCC submodule commit. These tests are excluded to allow successful OE self-test runs. * Two tests from the`codegen` modules now fail only on riscv64. Enable them on arm32/64 and x86-32/64 targets, while restricting them on riscv64 via `only-<target_arch>` tags. Bugzilla link - https://bugzilla.yoctoproject.org/show_bug.cgi?id=15944 Test Results Summary: +-----------+--------+---------+ | Machine | Passed | Ignored | +-----------+--------+---------+ | arm-32 | 28,664 | 1,451 | | arm-64 | 28,748 | 1,396 | | x86-32 | 28,657 | 1,432 | | x86-64 | 28,904 | 1,213 | | riscv-64 | 28,722 | 1,421 | +-----------+--------+---------+ (From OE-Core rev: 5afc9bdbabfdbcb784ceb637926111e6c7648f41) Signed-off-by: Jayasurya Maganuru <Maganuru.Jayasurya@windriver.com> Signed-off-by: Deepesh Varatharajan <Deepesh.Varatharajan@windriver.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.7 KiB
BlitzBasic
53 lines
1.7 KiB
BlitzBasic
SUMMARY = "Rust standard libaries"
|
|
HOMEPAGE = "http://www.rust-lang.org"
|
|
SECTION = "devel"
|
|
LICENSE = "(MIT | Apache-2.0) & Unicode-3.0"
|
|
LIC_FILES_CHKSUM = "file://../../COPYRIGHT;md5=11a3899825f4376896e438c8c753f8dc"
|
|
|
|
require rust-source.inc
|
|
|
|
# The dummy crate named `sysroot` represents the standard library target.
|
|
#
|
|
# See fd4c81f4c19e ("Add a `sysroot` crate to represent the standard library crates")
|
|
# https://github.com/rust-lang/rust/pull/108865/
|
|
S = "${RUSTSRC}/library/sysroot"
|
|
|
|
RUSTLIB_DEP = ""
|
|
inherit cargo
|
|
|
|
CVE_PRODUCT = "rust"
|
|
|
|
DEPENDS:append:libc-musl = " libunwind"
|
|
# rv32 does not have libunwind ported yet
|
|
DEPENDS:remove:riscv32 = "libunwind"
|
|
DEPENDS:remove:riscv64 = "libunwind"
|
|
|
|
# Embed bitcode in order to allow compiling both with and without LTO
|
|
RUSTFLAGS += "-Cembed-bitcode=yes"
|
|
# Ensure that user code can't access the dependencies of the standard library
|
|
RUSTFLAGS += "-Zforce-unstable-if-unmarked"
|
|
# Needed so cargo can find libbacktrace
|
|
RUSTFLAGS += "-L ${STAGING_LIBDIR} -C link-arg=-Wl,-soname,libstd.so"
|
|
|
|
CARGO_FEATURES ?= "panic-unwind backtrace"
|
|
CARGO_BUILD_FLAGS += "--features '${CARGO_FEATURES}'"
|
|
CARGO_VENDORING_DIRECTORY = "${RUSTSRC}/vendor"
|
|
|
|
do_compile:prepend () {
|
|
export CARGO_TARGET_DIR="${B}"
|
|
# For Rust 1.13.0 and newer
|
|
export RUSTC_BOOTSTRAP="1"
|
|
}
|
|
|
|
do_install () {
|
|
mkdir -p ${D}${rustlibdir}
|
|
|
|
# With the incremental build support added in 1.24, the libstd deps directory also includes dependency
|
|
# files that get installed. Those are really only needed to incrementally rebuild the libstd library
|
|
# itself and don't need to be installed.
|
|
rm -f ${B}/${RUST_TARGET_SYS}/${BUILD_DIR}/deps/*.d
|
|
cp ${B}/${RUST_TARGET_SYS}/${BUILD_DIR}/deps/* ${D}${rustlibdir}
|
|
}
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|