mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 03:19:41 +01:00
43a4d45f51
This helps in switching toolchains cleanly for kernel build between gcc and clang Currently, some kernels allow building with clang but not all the distro might use clang as default system compiler but kernel may demand gcc which is provided via KERNEL_* variables, however kernel does use OBJCOPY at places during build and it maybe set to use llvm objcopy when using clang. That should be a deliberate setting when clang is used for kernel as well, otherwise it should use binutils provided objcopy (From OE-Core rev: 17b409f2fd97894e0943d13c2cb0d52abde647e3) Signed-off-by: Khem Raj <raj.khem@gmail.com> Cc: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.2 KiB
BlitzBasic
41 lines
1.2 KiB
BlitzBasic
SUMMARY = "UProbes kernel module for SystemTap"
|
|
HOMEPAGE = "https://sourceware.org/systemtap/"
|
|
require systemtap_git.inc
|
|
|
|
DEPENDS = "systemtap virtual/kernel"
|
|
|
|
# On systems without CONFIG_UTRACE, this package is empty.
|
|
ALLOW_EMPTY:${PN} = "1"
|
|
|
|
inherit module-base gettext
|
|
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemtap:"
|
|
|
|
FILES:${PN} += "${datadir}/systemtap/runtime/uprobes"
|
|
|
|
# Compile and install the uprobes kernel module on machines with utrace
|
|
# support. Note that staprun expects it in the systemtap/runtime directory,
|
|
# not in /lib/modules.
|
|
do_compile() {
|
|
if grep -q "CONFIG_UTRACE=y" ${STAGING_KERNEL_BUILDDIR}/.config
|
|
then
|
|
unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS CC LD CPP
|
|
oe_runmake CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
|
|
AR="${KERNEL_AR}" OBJCOPY="${KERNEL_OBJCOPY}" \
|
|
-C ${STAGING_KERNEL_DIR} scripts
|
|
oe_runmake KDIR=${STAGING_KERNEL_DIR} \
|
|
M="${S}/runtime/uprobes/" \
|
|
CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
|
|
AR="${KERNEL_AR}" OBJCOPY="${KERNEL_OBJCOPY}" \
|
|
-C "${S}/runtime/uprobes/"
|
|
fi
|
|
}
|
|
|
|
do_install() {
|
|
if [ -e "${S}/runtime/uprobes/uprobes.ko" ]
|
|
then
|
|
install -d ${D}${datadir}/systemtap/runtime/uprobes/
|
|
install -m 0644 ${S}/runtime/uprobes/uprobes.ko ${D}${datadir}/systemtap/runtime/uprobes/
|
|
fi
|
|
}
|