mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 10:13:03 +01:00
7ca5822635
For cases when systemap module compilation happens on host in cross-compilation mode, and it is desirable to minimize systemtap presense on target we need to have just smallest possible set of utilties that are required to run compiled modules. Introduce new "translator" PACKAGECONFIG, if it is not set it would mean that just minimal set of run-time utilities will be included in the package. For run-time only systemtap build variant use PACKAGECONFIG_pn-systemtap = "" or PACKAGECONFIG_pn-systemtap = "monitor" Suggested-by: Taras Kondratiuk <takondra@cisco.com> (From OE-Core rev: a22b8140c6924eb3b3cd7b5bea66a4d3ed413807) Signed-off-by: Victor Kamensky <kamensky@cisco.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.4 KiB
BlitzBasic
37 lines
1.4 KiB
BlitzBasic
SUMMARY = "Script-directed dynamic tracing and performance analysis tool for Linux"
|
|
HOMEPAGE = "https://sourceware.org/systemtap/"
|
|
|
|
require systemtap_git.inc
|
|
|
|
DEPENDS = "elfutils"
|
|
|
|
EXTRA_OECONF += "--with-libelf=${STAGING_DIR_TARGET} --without-rpm \
|
|
--without-nss --without-avahi --without-dyninst \
|
|
--disable-server --disable-grapher --enable-prologues \
|
|
--with-python3 --without-python2-probes \
|
|
ac_cv_prog_have_javac=no \
|
|
ac_cv_prog_have_jar=no "
|
|
|
|
STAP_DOCS ?= "--disable-docs --disable-publican --disable-refdocs"
|
|
|
|
EXTRA_OECONF += "${STAP_DOCS} "
|
|
|
|
PACKAGECONFIG ??= "translator sqlite monitor python3-probes"
|
|
PACKAGECONFIG[translator] = "--enable-translator,--disable-translator,boost,python3-core bash perl"
|
|
PACKAGECONFIG[libvirt] = "--enable-libvirt,--disable-libvirt,libvirt"
|
|
PACKAGECONFIG[sqlite] = "--enable-sqlite,--disable-sqlite,sqlite3"
|
|
PACKAGECONFIG[monitor] = "--enable-monitor,--disable-monitor,ncurses json-c"
|
|
PACKAGECONFIG[python3-probes] = "--with-python3-probes,--without-python3-probes,python3-setuptools-native"
|
|
|
|
inherit autotools gettext pkgconfig distutils3-base
|
|
|
|
do_install_append () {
|
|
if [ ! -f ${D}${bindir}/stap ]; then
|
|
# translator disabled case, need to leave only minimal runtime
|
|
rm -rf ${D}${datadir}/${PN}
|
|
rm ${D}${libexecdir}/${PN}/stap-env
|
|
fi
|
|
}
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|