mirror of
https://git.yoctoproject.org/poky
synced 2026-03-31 11:02:21 +02:00
2efd475a98
1. Upgrade to fix the several CVEs: CVE-2014-0488, CVE-2014-0490 2. Remove apt-0.9.9.4-CVE-2014-0478.patch, which was backport. 3. Romve no-ko-translation.patch, apt-1.0.9.9 has ko translation 4. Update use-host.patch no-curl.patch db_linking_hack.patch and noconfigure.patch 5. Not build the test cases since it requires gtest 6. install libapt-private.so.* to libdir, otherwise this file is not installed into sysroot for native, and apt-get will use host's, and lead to fail 7. Revert apt commit[a2a75ff45]"always run 'dpkg --configure -a' at the end of our dpkg callings" for native package, otherwise the postscript for these installed packages will be run, and fail since the rootfs dir is not considered 8. Add lzma dependency by PACKAGECONFIG for target, and add xz dependency for native 9. Support to compile apt-native on centos6 (From OE-Core rev: 7dd4a53a99277b46696dea5558fa321a2267af0a) Signed-off-by: Roy Li <rongqing.li@windriver.com> Acked-by: Aníbal Limón <anibal.limon@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
75 lines
2.7 KiB
PHP
75 lines
2.7 KiB
PHP
require apt.inc
|
|
inherit native
|
|
|
|
DEPENDS += "dpkg-native gettext-native db-native curl-native xz-native"
|
|
PACKAGES = ""
|
|
USE_NLS = "yes"
|
|
|
|
SRC_URI += "file://db_linking_hack.patch \
|
|
file://0001-Revert-always-run-dpkg-configure-a-at-the-end-of-our.patch \
|
|
file://0001-remove-Wsuggest-attribute-from-CFLAGS.patch \
|
|
file://0001-fix-the-gcc-version-check.patch \
|
|
"
|
|
|
|
python do_install () {
|
|
bb.build.exec_func('do_install_base', d)
|
|
bb.build.exec_func('do_install_config', d)
|
|
}
|
|
|
|
python do_install_config () {
|
|
indir = os.path.dirname(d.getVar('FILE',1))
|
|
infile = file(oe.path.join(indir, 'files', 'apt.conf'), 'r')
|
|
data = infile.read()
|
|
infile.close()
|
|
|
|
data = d.expand(data)
|
|
|
|
outdir = oe.path.join(d.getVar('D', True), d.getVar('sysconfdir', True), 'apt')
|
|
if not os.path.exists(outdir):
|
|
os.makedirs(outdir)
|
|
|
|
outpath = oe.path.join(outdir, 'apt.conf.sample')
|
|
if not os.path.exists(outpath):
|
|
outfile = file(outpath, 'w')
|
|
outfile.write(data)
|
|
outfile.close()
|
|
}
|
|
|
|
do_install_base () {
|
|
install -d ${D}${bindir}
|
|
install -m 0755 bin/apt-cdrom ${D}${bindir}/
|
|
install -m 0755 bin/apt-get ${D}${bindir}/
|
|
install -m 0755 bin/apt-config ${D}${bindir}/
|
|
install -m 0755 bin/apt-cache ${D}${bindir}/
|
|
install -m 0755 bin/apt-sortpkgs ${D}${bindir}/
|
|
install -m 0755 bin/apt-extracttemplates ${D}${bindir}/
|
|
install -m 0755 bin/apt-ftparchive ${D}${bindir}/
|
|
|
|
oe_libinstall -so -C bin libapt-private ${D}${libdir}/
|
|
|
|
eval `cat environment.mak | grep ^GLIBC_VER | sed -e's, = ,=,'`
|
|
eval `cat environment.mak | grep ^LIBSTDCPP_VER | sed -e's, = ,=,'`
|
|
oe_libinstall -so -C bin libapt-pkg$GLIBC_VER$LIBSTDCPP_VER ${D}${libdir}/
|
|
ln -sf libapt-pkg$GLIBC_VER$LIBSTDCPP_VER.so ${D}${libdir}/libapt-pkg.so
|
|
oe_libinstall -so -C bin libapt-inst$GLIBC_VER$LIBSTDCPP_VER ${D}${libdir}/
|
|
ln -sf libapt-inst$GLIBC_VER$LIBSTDCPP_VER.so ${D}${libdir}/libapt-inst.so
|
|
|
|
install -d ${D}${libdir}/apt/methods
|
|
install -m 0755 bin/methods/* ${D}${libdir}/apt/methods/
|
|
|
|
install -d ${D}${libdir}/dpkg/methods/apt
|
|
install -m 0644 ${S}/dselect/desc.apt ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0644 ${S}/dselect/names ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0755 ${S}/dselect/install ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0755 ${S}/dselect/setup ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0755 ${S}/dselect/update ${D}${libdir}/dpkg/methods/apt/
|
|
|
|
install -d ${D}${sysconfdir}/apt
|
|
install -d ${D}${sysconfdir}/apt/apt.conf.d
|
|
install -d ${D}${sysconfdir}/apt/preferences.d
|
|
install -d ${D}${localstatedir}/lib/apt/lists/partial
|
|
install -d ${D}${localstatedir}/cache/apt/archives/partial
|
|
|
|
install -d ${D}${localstatedir}/log/apt/
|
|
}
|