mirror of
https://git.yoctoproject.org/poky
synced 2026-02-11 19:23:03 +01:00
82a99a4cee
For reasons that are now shrouded in obscurity, autotools.bbclass has long contained a special heuristic to avoid attempting to run autoreconf when building autoconf or automake themselves. However, the wildcard test against PN which is used there is problematic when trying to build another package whose name happens to start with "autoconf", and in any case it is silly to do this test at runtime for every package. The individual recipes for autoconf and automake can just as easily suppress the behaviour that they don't want by providing a custom do_configure() method which just runs configure. (From OE-Core rev: a87db6f8dea71cbb7ead9285ff8af0e28cf75604) Signed-off-by: Phil Blundell <pb@pbcl.net> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.5 KiB
PHP
37 lines
1.5 KiB
PHP
SUMMARY = "A GNU tool that procude shell scripts to automatically configure software."
|
|
DESCRIPTION = "Autoconf is an extensible package of M4 macros that produce shell scripts to automatically \
|
|
configure software source code packages. Autoconf creates a configuration script for a package from a template \
|
|
file that lists the operating system features that the package can use, in the form of M4 macro calls."
|
|
LICENSE = "GPLv3"
|
|
HOMEPAGE = "http://www.gnu.org/software/autoconf/"
|
|
SECTION = "devel"
|
|
DEPENDS += "m4-native"
|
|
DEPENDS_virtclass-native = "m4-native gnu-config-native"
|
|
DEPENDS_virtclass-nativesdk = "nativesdk-m4 nativesdk-gnu-config"
|
|
RDEPENDS_${PN} = "m4 gnu-config"
|
|
RDEPENDS_${PN}_virtclass-native = "m4-native gnu-config-native"
|
|
RDEPENDS_${PN}_virtclass-nativesdk = "nativesdk-m4 nativesdk-gnu-config"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/autoconf/autoconf-${PV}.tar.gz \
|
|
file://program_prefix.patch"
|
|
|
|
inherit autotools
|
|
|
|
do_configure() {
|
|
oe_runconf
|
|
}
|
|
|
|
do_install_append() {
|
|
rm -rf ${D}${datadir}/emacs
|
|
|
|
# Some distros have both /bin/perl and /usr/bin/perl, but we set perl location
|
|
# for target as /usr/bin/perl, so fix it to /usr/bin/perl.
|
|
for i in autoheader autom4te autoreconf autoscan autoupdate ifnames; do
|
|
if [ -f ${D}${bindir}/$i ]; then
|
|
sed -i -e '1s,#!.*perl,#! ${USRBINPATH}/perl,' \
|
|
-e 's,exec .*/bin/perl \(.*\) exec .*/bin/perl \(.*\),exec ${USRBINPATH}/perl \1 exec ${USRBINPATH}/perl \2,' \
|
|
${D}${bindir}/$i
|
|
fi
|
|
done
|
|
}
|