mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 12:32:11 +02:00
d45bbc5c75
Fixes sstate relocation due to the path to /etc/rpm being baked into the libraries - this manifested in the form of the following assertion at runtime: python: dbconfig.c:493: db3New: Assertion `dbOpts != ((void *)0) && *dbOpts != '\0'' failed. Fixes [YOCTO #2753]. (From OE-Core rev: b5028cc84ad7c40c51cadbdf7fdc892cde4462cb) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.5 KiB
BlitzBasic
45 lines
1.5 KiB
BlitzBasic
DESCRIPTION = "createrepo creates rpm-metadata for rpms to build the repository"
|
|
HOMEPAGE = "http://createrepo.baseurl.org/"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=18810669f13b87348459e611d31ab760"
|
|
|
|
RDEPENDS_${PN}_virtclass-native += "libxml2-native rpm-native"
|
|
|
|
PR = "r7"
|
|
|
|
SRC_URI= "http://createrepo.baseurl.org/download/${BP}.tar.gz \
|
|
file://fix-native-install.patch \
|
|
file://python-scripts-should-use-interpreter-from-env.patch \
|
|
file://createrepo-rpm549.patch \
|
|
file://rpm-createsolvedb.py \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "3e9ccf4abcffe3f49af078c83611eda2"
|
|
SRC_URI[sha256sum] = "a73ae11a0dcde8bde36d900bc3f7f8f1083ba752c70a5c61b72d1e1e7608f21b"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
do_install () {
|
|
oe_runmake -e 'DESTDIR=${D}' install
|
|
install -m 0755 ${WORKDIR}/rpm-createsolvedb.py ${D}${bindir}/
|
|
}
|
|
|
|
# Wrap the python script since the native python is
|
|
# ${bindir}/python-native/python, and the "#! /usr/bin/env python" can't
|
|
# find it since it is not in PATH.
|
|
do_install_append_virtclass-native () {
|
|
# Not all the python scripts should be wrapped since some of
|
|
# them are modules (be imported).
|
|
for i in ${D}${datadir}/createrepo/genpkgmetadata.py \
|
|
${D}${datadir}/createrepo/modifyrepo.py \
|
|
${D}${bindir}/rpm-createsolvedb.py ; do
|
|
create_wrapper $i ${STAGING_BINDIR_NATIVE}/python-native/python
|
|
done
|
|
|
|
create_wrapper ${D}/${bindir}/createrepo \
|
|
RPM_USRLIBRPM=${STAGING_LIBDIR_NATIVE}/rpm \
|
|
RPM_ETCRPM=${STAGING_ETCDIR_NATIVE}/rpm \
|
|
RPM_LOCALEDIRRPM=${STAGING_DATADIR_NATIVE}/locale
|
|
}
|