mirror of
https://git.yoctoproject.org/poky
synced 2026-02-24 02:19:39 +01:00
a197c96039
If sqlite is built with -DSQLITE_DQS=0 in accordance with https://sqlite.org/quirks.html#dblquote, migration to version 1.2 of the history database would fail with: History database cannot be created: .../var/lib/dnf/history.sqlite. Error: SQLite error on ":memory:": Executing an SQL statement failed: no such column: 1.2 (From OE-Core rev: 61d34df201cf6498854fa9258c320437b97071a4) Signed-off-by: Peter Kjellerstedt <pkj@axis.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.6 KiB
BlitzBasic
35 lines
1.6 KiB
BlitzBasic
SUMMARY = "Library providing simplified C and Python API to libsolv"
|
|
LICENSE = "LGPLv2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
|
|
|
|
SRC_URI = "git://github.com/rpm-software-management/libdnf;branch=dnf-4-master \
|
|
file://0001-FindGtkDoc.cmake-drop-the-requirement-for-GTKDOC_SCA.patch \
|
|
file://0004-Set-libsolv-variables-with-pkg-config-cmake-s-own-mo.patch \
|
|
file://0001-Get-parameters-for-both-libsolv-and-libsolvext-libdn.patch \
|
|
file://0001-Add-WITH_TESTS-option.patch \
|
|
file://0001-Look-fo-sphinx-only-if-documentation-is-actually-ena.patch \
|
|
file://0001-Use-single-quotes-around-string-literals-used-in-SQL.patch \
|
|
"
|
|
|
|
SRCREV = "8330eea6985c4e4b53796f858de5b6b38b1ddf5c"
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS = "glib-2.0 libsolv libcheck librepo rpm gtk-doc libmodulemd json-c swig-native"
|
|
|
|
inherit gtk-doc gobject-introspection cmake pkgconfig distutils3-base
|
|
|
|
EXTRA_OECMAKE = " -DPYTHON_INSTALL_DIR=${PYTHON_SITEPACKAGES_DIR} -DWITH_MAN=OFF -DPYTHON_DESIRED=3 \
|
|
${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DWITH_GIR=ON', '-DWITH_GIR=OFF', d)} \
|
|
-DWITH_TESTS=OFF \
|
|
-DWITH_ZCHUNK=OFF \
|
|
-DWITH_HTML=OFF \
|
|
"
|
|
EXTRA_OECMAKE_append_class-native = " -DWITH_GIR=OFF"
|
|
EXTRA_OECMAKE_append_class-nativesdk = " -DWITH_GIR=OFF"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
PNBLACKLIST[libdnf] ?= "${@bb.utils.contains('PACKAGE_CLASSES', 'package_rpm', '', 'Does not build without package_rpm in PACKAGE_CLASSES due disabled rpm support in libsolv', d)}"
|
|
|