mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 09:16:36 +01:00
d73a813aa2
The package_qa task isn't required for cross builds, so delete it along with the other packaging tasks to match native.bbclass. [ YOCTO #7934 ] (From OE-Core rev: 24a6590e85c941a73ea852b91939db8c0835d683) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
76 lines
2.1 KiB
Plaintext
76 lines
2.1 KiB
Plaintext
inherit relocatable
|
|
|
|
# Cross packages are built indirectly via dependency,
|
|
# no need for them to be a direct target of 'world'
|
|
EXCLUDE_FROM_WORLD = "1"
|
|
|
|
CLASSOVERRIDE = "class-cross"
|
|
PACKAGES = ""
|
|
PACKAGES_DYNAMIC = ""
|
|
PACKAGES_DYNAMIC_class-native = ""
|
|
|
|
HOST_ARCH = "${BUILD_ARCH}"
|
|
HOST_VENDOR = "${BUILD_VENDOR}"
|
|
HOST_OS = "${BUILD_OS}"
|
|
HOST_PREFIX = "${BUILD_PREFIX}"
|
|
HOST_CC_ARCH = "${BUILD_CC_ARCH}"
|
|
HOST_LD_ARCH = "${BUILD_LD_ARCH}"
|
|
HOST_AS_ARCH = "${BUILD_AS_ARCH}"
|
|
|
|
STAGING_DIR_HOST = "${STAGING_DIR}/${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
|
|
|
|
PACKAGE_ARCH = "${BUILD_ARCH}"
|
|
|
|
export PKG_CONFIG_DIR = "${exec_prefix}/lib/pkgconfig"
|
|
export PKG_CONFIG_SYSROOT_DIR = ""
|
|
|
|
CPPFLAGS = "${BUILD_CPPFLAGS}"
|
|
CFLAGS = "${BUILD_CFLAGS}"
|
|
CXXFLAGS = "${BUILD_CFLAGS}"
|
|
LDFLAGS = "${BUILD_LDFLAGS}"
|
|
LDFLAGS_build-darwin = "-L${STAGING_LIBDIR_NATIVE}"
|
|
|
|
TOOLCHAIN_OPTIONS = ""
|
|
|
|
DEPENDS_GETTEXT = "gettext-native"
|
|
|
|
# Path mangling needed by the cross packaging
|
|
# Note that we use := here to ensure that libdir and includedir are
|
|
# target paths.
|
|
target_base_prefix := "${base_prefix}"
|
|
target_prefix := "${prefix}"
|
|
target_exec_prefix := "${exec_prefix}"
|
|
target_base_libdir = "${target_base_prefix}/${baselib}"
|
|
target_libdir = "${target_exec_prefix}/${baselib}"
|
|
target_includedir := "${includedir}"
|
|
|
|
# Overrides for paths
|
|
CROSS_TARGET_SYS_DIR = "${TARGET_SYS}"
|
|
prefix = "${STAGING_DIR_NATIVE}${prefix_native}"
|
|
base_prefix = "${STAGING_DIR_NATIVE}"
|
|
exec_prefix = "${STAGING_DIR_NATIVE}${prefix_native}"
|
|
bindir = "${exec_prefix}/bin/${CROSS_TARGET_SYS_DIR}"
|
|
sbindir = "${bindir}"
|
|
base_bindir = "${bindir}"
|
|
base_sbindir = "${bindir}"
|
|
libdir = "${exec_prefix}/lib/${CROSS_TARGET_SYS_DIR}"
|
|
libexecdir = "${exec_prefix}/libexec/${CROSS_TARGET_SYS_DIR}"
|
|
|
|
do_populate_sysroot[sstate-inputdirs] = "${SYSROOT_DESTDIR}/${STAGING_DIR_NATIVE}/"
|
|
do_populate_sysroot[stamp-extra-info] = ""
|
|
do_packagedata[stamp-extra-info] = ""
|
|
|
|
do_install () {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
}
|
|
|
|
USE_NLS = "no"
|
|
|
|
deltask package
|
|
deltask packagedata
|
|
deltask package_qa
|
|
deltask package_write_ipk
|
|
deltask package_write_deb
|
|
deltask package_write_rpm
|
|
deltask package_write
|