mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 11:29:40 +01:00
d541a30726
Because of differences in how RDEPENDS works for native/target, add libxml2 and libxslt to RDEPENDS (so that native dependencies work), but also add libxml2-utils (for xmllint) and libxslt-bin (for xsltproc) to target RDEPENDS. Also add libxml2-native to DEPENDS as that is needed for the docbook-(xml,xsl)-native catalog to be generated. (From OE-Core rev: b571315acb59f61335c20849d2ce7f5059258c1a) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.2 KiB
BlitzBasic
41 lines
1.2 KiB
BlitzBasic
SUMMARY = "A shell-script tool for converting XML files to various formats"
|
|
HOMEPAGE = "https://releases.pagure.org/xmlto/"
|
|
SECTION = "docs/xmlto"
|
|
LICENSE = "GPLv2"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
|
|
|
|
SRC_URI = "https://releases.pagure.org/xmlto/xmlto-${PV}.tar.gz \
|
|
file://configure.in-drop-the-test-of-xmllint-and-xsltproc.patch \
|
|
"
|
|
SRC_URI[md5sum] = "a1fefad9d83499a15576768f60f847c6"
|
|
SRC_URI[sha256sum] = "2f986b7c9a0e9ac6728147668e776d405465284e13c74d4146c9cbc51fd8aad3"
|
|
|
|
inherit autotools
|
|
|
|
DEPENDS = "libxml2-native"
|
|
|
|
RDEPENDS_${PN} = "docbook-xml-dtd4 \
|
|
docbook-xsl-stylesheets \
|
|
util-linux \
|
|
libxml2 \
|
|
libxslt \
|
|
bash \
|
|
"
|
|
RDEPENDS_${PN}_append_class-target = " \
|
|
libxml2-utils \
|
|
libxslt-bin \
|
|
coreutils \
|
|
"
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_TAIL=tail"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
EXTRA_OECONF_append = " BASH=/bin/bash GCP=/bin/cp XMLLINT=xmllint XSLTPROC=xsltproc"
|
|
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}${bindir}/xmlto XML_CATALOG_FILES=${sysconfdir}/xml/catalog
|
|
}
|
|
|
|
do_populate_sysroot[rdeptask] = "do_populate_sysroot"
|