mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 01:36:38 +01:00
f8f2adab63
If we are building a systemd image with 'sysvinit' not in DISTRO_FEATURES, the initscripts should not be installed into the image, as they are useless. What's more, we as now support executing scripts under /etc/rcS.d, the boot time will be increased by these scripts as the systemd will try to translate them into temporary service files. These init scritps are actually needed only when 'sysvinit' is in DISTRO_FEATURES. (From OE-Core rev: 74b931909e58fc581bb52c1af1f3ae26602980f3) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.4 KiB
BlitzBasic
48 lines
1.4 KiB
BlitzBasic
#
|
|
# Copyright (C) 2007 OpenedHand Ltd.
|
|
#
|
|
|
|
SUMMARY = "Minimal boot requirements"
|
|
DESCRIPTION = "The minimal set of packages required to boot the system"
|
|
LICENSE = "MIT"
|
|
PR = "r17"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
inherit packagegroup
|
|
|
|
#
|
|
# Set by the machine configuration with packages essential for device bootup
|
|
#
|
|
MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
|
|
MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
|
|
|
|
# Distro can override the following VIRTUAL-RUNTIME providers:
|
|
VIRTUAL-RUNTIME_dev_manager ?= "udev"
|
|
VIRTUAL-RUNTIME_login_manager ?= "busybox"
|
|
VIRTUAL-RUNTIME_init_manager ?= "sysvinit"
|
|
VIRTUAL-RUNTIME_initscripts ?= "initscripts"
|
|
VIRTUAL-RUNTIME_keymaps ?= "keymaps"
|
|
|
|
SYSVINIT_SCRIPTS = "${@bb.utils.contains('MACHINE_FEATURES', 'rtc', 'busybox-hwclock', '', d)} \
|
|
modutils-initscripts \
|
|
init-ifupdown \
|
|
${VIRTUAL-RUNTIME_initscripts} \
|
|
"
|
|
|
|
RDEPENDS_${PN} = "\
|
|
base-files \
|
|
base-passwd \
|
|
busybox \
|
|
${@bb.utils.contains("DISTRO_FEATURES", "sysvinit", "${SYSVINIT_SCRIPTS}", "", d)} \
|
|
${@bb.utils.contains("MACHINE_FEATURES", "keyboard", "${VIRTUAL-RUNTIME_keymaps}", "", d)} \
|
|
netbase \
|
|
${VIRTUAL-RUNTIME_login_manager} \
|
|
${VIRTUAL-RUNTIME_init_manager} \
|
|
${VIRTUAL-RUNTIME_dev_manager} \
|
|
${VIRTUAL-RUNTIME_update-alternatives} \
|
|
${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
|
|
|
|
RRECOMMENDS_${PN} = "\
|
|
${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
|