mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 01:36:38 +01:00
4a17e7c58b
The new upstream commit incorporates the following fix to update-alternatives from Chen Qi <Qi.Chen@windriver.com>: update-alternatives: avoid double slash problem The link path stored by update-alternatives should always be absolute and so we do not need to add an additional slash when joining to $OPKG_OFFLINE_ROOT. (From OE-Core rev: 49dca57255a61b05bb93dbc5d912a9d06d024058) Signed-off-by: Paul Barker <paul@paulbarker.me.uk> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
36 lines
1.3 KiB
BlitzBasic
36 lines
1.3 KiB
BlitzBasic
SUMMARY = "Additional utilities for the opkg package manager"
|
|
SUMMARY_update-alternatives-opkg = "Utility for managing the alternatives system"
|
|
SECTION = "base"
|
|
HOMEPAGE = "http://code.google.com/p/opkg/"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://opkg.py;beginline=1;endline=18;md5=15917491ad6bf7acc666ca5f7cc1e083"
|
|
PROVIDES += "virtual/update-alternatives"
|
|
|
|
SRCREV = "53274f087565fd45d8452c5367997ba6a682a37a"
|
|
PV = "0.1.8+git${SRCPV}"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/opkg-utils"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
|
|
PYTHONRDEPS = "python python-shell python-io python-math python-crypt python-logging python-fcntl python-subprocess python-pickle python-compression python-textutils python-stringold"
|
|
PYTHONRDEPS_class-native = ""
|
|
|
|
PACKAGECONFIG = "python"
|
|
PACKAGECONFIG[python] = ",,,${PYTHONRDEPS}"
|
|
|
|
do_install() {
|
|
oe_runmake PREFIX=${prefix} DESTDIR=${D} install
|
|
}
|
|
|
|
PACKAGES =+ "update-alternatives-opkg"
|
|
FILES_update-alternatives-opkg = "${bindir}/update-alternatives"
|
|
RPROVIDES_update-alternatives-opkg = "update-alternatives update-alternatives-cworth"
|
|
RREPLACES_update-alternatives-opkg = "update-alternatives-cworth"
|
|
RCONFLICTS_update-alternatives-opkg = "update-alternatives-cworth"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|