mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 02:03:04 +01:00
ce5cc411bb
(From OE-Core rev: df4224f151c3d5a7f6fd33ed44abd2e3bfc5c8b0) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.1 KiB
PHP
45 lines
1.1 KiB
PHP
SUMMARY = "System performance tools"
|
|
DESCRIPTION = "The sysstat utilities are a collection of performance monitoring tools for Linux."
|
|
HOMEPAGE = "http://sebastien.godard.pagesperso-orange.fr/"
|
|
LICENSE = "GPLv2+"
|
|
SECTION = "console/utils"
|
|
|
|
SRC_URI = "http://pagesperso-orange.fr/sebastien.godard/sysstat-${PV}.tar.xz \
|
|
file://99_sysstat \
|
|
"
|
|
|
|
inherit autotools-brokensep gettext
|
|
|
|
EXTRA_OECONF += "--disable-sensors"
|
|
EXTRA_OEMAKE += 'LFLAGS=""'
|
|
|
|
do_configure_prepend() {
|
|
export sa_lib_dir=${libdir}/sa
|
|
}
|
|
|
|
do_install() {
|
|
autotools_do_install
|
|
|
|
# don't install /var/log/sa when populating rootfs. Do it through volatile
|
|
|
|
rm -rf ${D}/var
|
|
install -d ${D}/etc/default/volatiles
|
|
install -m 0644 ${WORKDIR}/99_sysstat ${D}/etc/default/volatiles
|
|
}
|
|
|
|
pkg_postinst_${PN} () {
|
|
if [ -n "$D" ]; then
|
|
exit 0
|
|
fi
|
|
if [ -e /etc/init.d/populate-volatile.sh ]; then
|
|
/etc/init.d/populate-volatile.sh update
|
|
fi
|
|
}
|
|
|
|
|
|
FILES_${PN} += "${libdir}/sa"
|
|
FILES_${PN}-dbg += "${libdir}/sa/.debug/"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
LDFLAGS_append_libc-uclibc = " -lintl"
|