mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 00:38:45 +01:00
9adfa08360
INHIBIT_PACKAGE_STRIP variable will make debuginfo lose in shared library. The test cases of kmod contain kernel modules for many different architectures, strip and arch gets confused and throws errors. Pack kernel modules in test cases to avoid strip command failed. (From OE-Core rev: 3576399ed163cb3136ee1a2077622035d2033158) Signed-off-by: Chong Lu <Chong.Lu@windriver.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
79 lines
2.9 KiB
BlitzBasic
79 lines
2.9 KiB
BlitzBasic
# Copyright (C) 2012 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
require kmod.inc
|
|
|
|
DEPENDS += "zlib"
|
|
PROVIDES += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
|
|
RPROVIDES_${PN} += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
|
|
RCONFLICTS_${PN} += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
|
|
RREPLACES_${PN} += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
|
|
|
|
# to force user to remove old module-init-tools and replace them with kmod variants
|
|
RCONFLICTS_libkmod2 += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
|
|
|
|
# autotools set prefix to /usr, however we want them in /bin and /sbin
|
|
bindir = "${base_bindir}"
|
|
sbindir = "${base_sbindir}"
|
|
# libdir = "${base_libdir}"
|
|
|
|
do_install_append () {
|
|
install -dm755 ${D}${base_bindir}
|
|
install -dm755 ${D}${base_sbindir}
|
|
# add symlinks to kmod
|
|
ln -s ..${base_bindir}/kmod ${D}${base_bindir}/lsmod
|
|
for tool in insmod rmmod depmod modinfo modprobe; do
|
|
ln -s ..${base_bindir}/kmod ${D}${base_sbindir}/${tool}
|
|
done
|
|
# configuration directories
|
|
install -dm755 ${D}${base_libdir}/depmod.d
|
|
install -dm755 ${D}${base_libdir}/modprobe.d
|
|
install -dm755 ${D}${sysconfdir}/depmod.d
|
|
install -dm755 ${D}${sysconfdir}/modprobe.d
|
|
|
|
# install depmod.d file for search/ dir
|
|
install -Dm644 "${WORKDIR}/depmod-search.conf" "${D}${base_libdir}/depmod.d/search.conf"
|
|
|
|
if ${@base_contains('DISTRO_FEATURES', 'ptest', 'true', 'false', d)}; then
|
|
find testsuite -name *.ko -exec tar rf testmodule.tar {} \;
|
|
find testsuite -name *.ko -exec rm -f {} \;
|
|
fi
|
|
}
|
|
|
|
do_compile_prepend() {
|
|
sed -i 's/ac_pwd=/#ac_pwd=/' config.status ; sed -i "/#ac_pwd=/a\ac_pwd='.'" config.status
|
|
}
|
|
|
|
do_compile_ptest () {
|
|
oe_runmake buildtest-TESTS rootfs
|
|
}
|
|
|
|
do_install_ptest () {
|
|
install testmodule.tar ${D}${PTEST_PATH}
|
|
}
|
|
|
|
INSANE_SKIP_${PN}-ptest = "arch"
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "60"
|
|
|
|
ALTERNATIVE_kmod = "insmod modprobe rmmod modinfo bin-lsmod lsmod depmod"
|
|
|
|
ALTERNATIVE_LINK_NAME[insmod] = "${base_sbindir}/insmod"
|
|
ALTERNATIVE_LINK_NAME[modprobe] = "${base_sbindir}/modprobe"
|
|
ALTERNATIVE_LINK_NAME[rmmod] = "${base_sbindir}/rmmod"
|
|
ALTERNATIVE_LINK_NAME[modinfo] = "${base_sbindir}/modinfo"
|
|
ALTERNATIVE_LINK_NAME[bin-lsmod] = "${base_bindir}/lsmod"
|
|
|
|
ALTERNATIVE_LINK_NAME[lsmod] = "${base_sbindir}/lsmod"
|
|
ALTERNATIVE_TARGET[lsmod] = "${base_bindir}/lsmod.${BPN}"
|
|
|
|
ALTERNATIVE_LINK_NAME[depmod] = "${base_sbindir}/depmod"
|
|
|
|
PACKAGES =+ "libkmod ${PN}-bash-completion"
|
|
|
|
FILES_libkmod = "${base_libdir}/libkmod*${SOLIBS} ${libdir}/libkmod*${SOLIBS}"
|
|
FILES_${PN} += "${base_libdir}/depmod.d ${base_libdir}/modprobe.d"
|
|
FILES_${PN}-bash-completion = "${datadir}/bash-completion"
|