mirror of
https://git.yoctoproject.org/poky
synced 2026-02-14 04:33:03 +01:00
d2e1238fd6
It seems that 585324fee380109acd9986388f857f413a60b896 is no longer there in git and it has been rewritten to ffc3ad4945da69f3caa2b40e4eed715a9a8d9526 Change-Id: I9ffe8bd9bcef0d2dc5e6f6d3a6e4317bada8f4be (From OE-Core rev: b193c7f251542aa76cb5a4d6dcb71d15b27005eb) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
1.5 KiB
BlitzBasic
56 lines
1.5 KiB
BlitzBasic
SUMMARY = "H.264/MPEG-4 AVC video encoder"
|
|
DESCRIPTION = "A free software library and application for encoding video streams into the H.264/MPEG-4 AVC format."
|
|
HOMEPAGE = "http://www.videolan.org/developers/x264.html"
|
|
|
|
LICENSE = "GPLv2"
|
|
LICENSE_FLAGS = "commercial"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
DEPENDS = "yasm-native"
|
|
|
|
SRC_URI = "git://git.videolan.org/x264.git \
|
|
file://don-t-default-to-cortex-a9-with-neon.patch \
|
|
"
|
|
|
|
SRCREV = "ffc3ad4945da69f3caa2b40e4eed715a9a8d9526"
|
|
|
|
PV = "r2265+git${SRCPV}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit lib_package pkgconfig perlnative
|
|
|
|
X264_DISABLE_ASM = ""
|
|
X264_DISABLE_ASM_armv4 = "--disable-asm"
|
|
X264_DISABLE_ASM_armv5 = "--disable-asm"
|
|
X264_DISABLE_ASM_powerpc = "${@bb.utils.contains("TUNE_FEATURES", "spe", "--disable-asm", "", d)}"
|
|
|
|
EXTRA_OECONF = '--prefix=${prefix} \
|
|
--host=${HOST_SYS} \
|
|
--libdir=${libdir} \
|
|
--cross-prefix=${TARGET_PREFIX} \
|
|
--sysroot=${STAGING_DIR_TARGET} \
|
|
--enable-shared \
|
|
--enable-static \
|
|
--disable-lavf \
|
|
--disable-swscale \
|
|
--enable-pic \
|
|
${X264_DISABLE_ASM} \
|
|
'
|
|
|
|
do_configure() {
|
|
./configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
# Get rid of -e
|
|
EXTRA_OEMAKE = ""
|
|
AS = "${TARGET_PREFIX}gcc"
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
# PIC can't be enabled for 32-bit x86
|
|
INSANE_SKIP_${PN}_append_i586 = " textrel"
|
|
|