mirror of
https://git.yoctoproject.org/poky
synced 2026-05-18 23:27:53 +02:00
2c2e5dc146
On an x86_64 host, both 32-bit and 64-bit libraries need to be generated. It is fairly common that a user will have at least a few 32-bit programs on their x86_64 host system, so a pseudo wrapper for 32-bit is required to allow those programs to be successfully wrapped. Signed-off-by: Mark Hatle <Mark.Hatle@windriver.com>
48 lines
1.3 KiB
BlitzBasic
48 lines
1.3 KiB
BlitzBasic
DESCRIPTION = "Pseudo gives fake root capabilities to a normal user"
|
|
HOMEPAGE = "http://wiki.github.com/wrpseudo/pseudo/"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=243b725d71bb5df4a1e5920b344b86ad"
|
|
SECTION = "base"
|
|
LICENSE = "LGPL2.1"
|
|
DEPENDS = "sqlite3"
|
|
|
|
PV = "0.0+git${SRCPV}"
|
|
PR = "r12"
|
|
|
|
SRC_URI = "git://github.com/wrpseudo/pseudo.git;protocol=git \
|
|
file://static_sqlite.patch"
|
|
|
|
FILES_${PN} = "${libdir}/libpseudo.so ${bindir}/* ${localstatedir}/pseudo"
|
|
PROVIDES += "virtual/fakeroot"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit siteinfo
|
|
|
|
do_configure () {
|
|
:
|
|
}
|
|
|
|
do_compile () {
|
|
if [ "${SITEINFO_BITS}" == "64" ]; then
|
|
# We need the 32-bit libpseudo on a 64-bit machine...
|
|
./configure --prefix=${prefix} --with-sqlite=${STAGING_DIR_TARGET}${exec_prefix} --bits=32
|
|
oe_runmake 'CFLAGS=-m32' 'LIB=lib/pseudo/lib'
|
|
# prevent it from removing the lib, but keep everything else
|
|
make 'LIB=foo' distclean
|
|
fi
|
|
${S}/configure --prefix=${prefix} --with-sqlite=${STAGING_DIR_TARGET}${exec_prefix} --bits=${SITEINFO_BITS}
|
|
oe_runmake 'LIB=lib/pseudo/lib$(MARK64)'
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake 'DESTDIR=${D}' 'LIB=lib/pseudo/lib$(MARK64)' install
|
|
if [ "${SITEINFO_BITS}" == "64" ]; then
|
|
mkdir -p ${D}${prefix}/lib/pseudo/lib
|
|
cp lib/pseudo/lib/libpseudo.so ${D}${prefix}/lib/pseudo/lib/.
|
|
fi
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
|