mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 12:32:13 +02:00
744d68c369
lttng upstream had a different solution to the compaction build isses seen on mips. We switch our patch for a backport of the upstream solution. (From OE-Core rev: 459f746a198a8ae7840d783f5824fc14a44a8488) (From OE-Core rev: 10891d4d955f347c328cf8c099031f05f5c855a2) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Naveen Saini <naveen.kumar.saini@intel.com> Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.9 KiB
BlitzBasic
48 lines
1.9 KiB
BlitzBasic
SECTION = "devel"
|
|
SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
|
|
DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
|
|
HOMEPAGE = "https://lttng.org/"
|
|
LICENSE = "LGPL-2.1-only & GPL-2.0-only & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=0464cff101a009c403cd2ed65d01d4c4"
|
|
|
|
inherit module
|
|
|
|
include lttng-platforms.inc
|
|
|
|
SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://0009-Rename-genhd-wrapper-to-blkdev.patch \
|
|
file://0001-fix-mm-page_alloc-fix-tracepoint-mm_page_alloc_zone_.patch \
|
|
file://0002-fix-fs-Remove-flags-parameter-from-aops-write_begin-.patch \
|
|
file://0003-fix-workqueue-Fix-type-of-cpu-in-trace-event-v5.19.patch \
|
|
file://0001-fix-net-skb-introduce-kfree_skb_reason-v5.15.58.v5.1.patch \
|
|
file://0001-fix-compaction.patch \
|
|
"
|
|
|
|
# Use :append here so that the patch is applied also when using devupstream
|
|
SRC_URI:append = " file://0001-src-Kbuild-change-missing-CONFIG_TRACEPOINTS-to-warn.patch"
|
|
|
|
SRC_URI[sha256sum] = "6159d00e4e1d59546eec8d4a67e1aa39c1084ceb5e5afeb666eab4b8a5b5a9ee"
|
|
|
|
export INSTALL_MOD_DIR="kernel/lttng-modules"
|
|
|
|
EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
|
|
|
|
MODULES_MODULE_SYMVERS_LOCATION = "src"
|
|
|
|
do_install:append() {
|
|
# Delete empty directories to avoid QA failures if no modules were built
|
|
if [ -d ${D}/${nonarch_base_libdir} ]; then
|
|
find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
|
|
fi
|
|
}
|
|
|
|
python do_package:prepend() {
|
|
if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
|
|
bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
|
|
}
|
|
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRC_URI:class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.13"
|
|
SRCREV:class-devupstream = "7584cfc04914cb0842a986e9808686858b9c8630"
|
|
SRCREV_FORMAT ?= "lttng_git"
|