mirror of
https://git.yoctoproject.org/poky
synced 2026-05-01 06:32:11 +02:00
0f966a0ce6
It is not safe to call the 'file' command from multiple threads. When a file is checked with multiple threads in parallel, the file descriptors might get shared which makes the pipe handling lock up, leading to lock up in rpmbuild. And may lead to rarely deadlock on random recipes's do_package task. (From OE-Core rev: 167814b81ddac3934077b0ee91c0c6015fc02bfe) Signed-off-by: Changqing Li <changqing.li@windriver.com> Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
1.9 KiB
BlitzBasic
57 lines
1.9 KiB
BlitzBasic
SUMMARY = "File classification tool"
|
|
DESCRIPTION = "File attempts to classify files depending \
|
|
on their contents and prints a description if a match is found."
|
|
HOMEPAGE = "http://www.darwinsys.com/file/"
|
|
SECTION = "console/utils"
|
|
|
|
# two clause BSD
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;beginline=2;md5=0251eaec1188b20d9a72c502ecfdda1b"
|
|
|
|
DEPENDS = "file-replacement-native"
|
|
DEPENDS_class-native = "bzip2-replacement-native"
|
|
|
|
SRC_URI = "git://github.com/file/file.git \
|
|
file://0001-src-compress.c-correct-header-define-for-xz-lzma.patch \
|
|
file://0001-Fix-close_on_exec-multithreaded-decompression-issue.patch"
|
|
|
|
SRCREV = "87731415de945660b00f02207d8e9d986ef9b82e"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
PACKAGECONFIG ??= "bz2 lzma zlib"
|
|
PACKAGECONFIG[bz2] = "--enable-bzlib, --disable-bzlib, bzip2"
|
|
PACKAGECONFIG[lzma] = "--enable-xzlib, --disable-xzlib, xz"
|
|
PACKAGECONFIG[zlib] = "--enable-zlib, --disable-zlib, zlib"
|
|
|
|
EXTRA_OECONF += "--disable-libseccomp"
|
|
|
|
ALTERNATIVE_${PN} = "file"
|
|
ALTERNATIVE_LINK_NAME[file] = "${bindir}/file"
|
|
|
|
EXTRA_OEMAKE_append_class-target = " -e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
EXTRA_OEMAKE_append_class-nativesdk = " -e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
|
|
FILES_${PN} += "${datadir}/misc/*.mgc"
|
|
|
|
do_compile_append_class-native() {
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
PROVIDES_append_class-native = " file-replacement-native"
|
|
# Don't use NATIVE_PACKAGE_PATH_SUFFIX as that hides libmagic from anyone who
|
|
# depends on file-replacement-native.
|
|
bindir_append_class-native = "/file-native"
|