mirror of
https://git.yoctoproject.org/poky
synced 2026-02-23 01:49:40 +01:00
198512c27b
* there are few more autodetected compression libs
--disable-zlib disable zlib compression support [default=auto]
--disable-bzlib disable bz2lib compression support [default=auto]
--disable-xzlib disable liblzma/xz compression support
--disable-zstdlib disable zstdlib compression support [default=auto]
--disable-lzlib disable liblz (lzip) compression support
and lzlib was detected on my gentoo (even when it doesn't say that default
is auto detection)
I've noticed this, because I've reused sstate-cache from my gentoo build
in docker container with ubuntu-23.04 and esdk.oeSDKExtSelfTest.test_install_libraries_headers
test was now failing with:
Exception: subprocess.CalledProcessError: Command '/OE/build/poky/build/build-st-2023-03-12-esdk-patch1/esdk.oeSDKExtSelfTest.test_install_libraries_headers/build-st/tmp/work/x86_64-nativesdk-pokysdk-linux/buildtools-tarball/1.0-r0/recipe-sysroot-native/usr/bin/createrepo_c --update -q /OE/build/poky/build/build-st-2023-03-12-esdk-patch1/esdk.oeSDKExtSelfTest.test_install_libraries_headers/build-st/tmp/work/x86_64-nativesdk-pokysdk-linux/buildtools-tarball/1.0-r0/oe-sdk-repo' returned non-zero exit status 127.
Subprocess output:
/OE/build/poky/build/build-st-2023-03-12-esdk-patch1/esdk.oeSDKExtSelfTest.test_install_libraries_headers/build-st/tmp/work/x86_64-nativesdk-pokysdk-linux/buildtools-tarball/1.0-r0/recipe-sysroot-native/usr/bin/createrepo_c: error while loading shared libraries: liblz.so.1: cannot open shared object file: No such file or directory
and liblz.so.1 ended in createrepo_c.real because of libmagic.so from file-native-replacement.
* use PACKAGECONFIG for seccomp as well and keep it disabled as it was
explicitly disabled before (${@bb.utils.filter('DISTRO_FEATURES', 'seccomp', d)}
can be added to default PACKAGECONFIG later if someone finds it useful)
(From OE-Core rev: b7c51fe740f00f60c591099fe5c2155b2126068c)
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
59 lines
2.1 KiB
BlitzBasic
59 lines
2.1 KiB
BlitzBasic
SUMMARY = "File classification tool"
|
|
DESCRIPTION = "File attempts to classify files depending \
|
|
on their contents and prints a description if a match is found."
|
|
HOMEPAGE = "http://www.darwinsys.com/file/"
|
|
SECTION = "console/utils"
|
|
|
|
# two clause BSD
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;beginline=2;md5=0251eaec1188b20d9a72c502ecfdda1b"
|
|
|
|
DEPENDS = "file-replacement-native"
|
|
DEPENDS:class-native = "bzip2-replacement-native"
|
|
|
|
SRC_URI = "git://github.com/file/file.git;branch=master;protocol=https"
|
|
|
|
SRCREV = "b92eed41b1bc0739c5c5d70c444e0c574429321b"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
PACKAGECONFIG ??= "bz2 lzma zlib"
|
|
PACKAGECONFIG[bz2] = "--enable-bzlib, --disable-bzlib, bzip2"
|
|
PACKAGECONFIG[lzma] = "--enable-xzlib, --disable-xzlib, xz"
|
|
PACKAGECONFIG[zlib] = "--enable-zlib, --disable-zlib, zlib"
|
|
PACKAGECONFIG[zstdlib] = "--enable-zstdlib, --disable-zstdlib, zstd"
|
|
PACKAGECONFIG[lzlib] = "--enable-lzlib, --disable-lzlib, lzip"
|
|
PACKAGECONFIG[seccomp] = "--enable-libseccomp, --disable-libseccomp, libseccomp"
|
|
|
|
ALTERNATIVE:${PN} = "file"
|
|
ALTERNATIVE_LINK_NAME[file] = "${bindir}/file"
|
|
|
|
EXTRA_OEMAKE:append:class-target = " -e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
EXTRA_OEMAKE:append:class-nativesdk = " -e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
|
|
FILES:${PN} += "${datadir}/misc/*.mgc"
|
|
FILES:${PN}:append:class-nativesdk = " ${SDKPATHNATIVE}/environment-setup.d/file.sh"
|
|
|
|
do_compile:append:class-native() {
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install:append:class-native() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
do_install:append:class-nativesdk() {
|
|
mkdir -p ${D}${SDKPATHNATIVE}/environment-setup.d
|
|
cat <<- EOF > ${D}${SDKPATHNATIVE}/environment-setup.d/file.sh
|
|
export MAGIC="$OECORE_NATIVE_SYSROOT${datadir}/misc/magic.mgc"
|
|
EOF
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
PROVIDES:append:class-native = " file-replacement-native"
|
|
# Don't use NATIVE_PACKAGE_PATH_SUFFIX as that hides libmagic from anyone who
|
|
# depends on file-replacement-native.
|
|
bindir:append:class-native = "/file-native"
|