mirror of
https://git.yoctoproject.org/poky
synced 2026-03-02 13:29:40 +01:00
38a87b464e
* Author changed back from ETHER to OALDERS * Use CPAN_MIRROR for SRC_URI * Update HOMEPAGE * Update RPEPENDS for -ptest * Patch to skip TODO test cases For changes, see: https://metacpan.org/release/OALDERS/URI-5.17/changes License-Update: whitespace changes (From OE-Core rev: f5aad6f125b88920c7ff8dc749768fd2c3f40a89) Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
1.6 KiB
BlitzBasic
57 lines
1.6 KiB
BlitzBasic
SUMMARY = "Perl module to manipulate and access URI strings"
|
|
DESCRIPTION = "This package contains the URI.pm module with friends. \
|
|
The module implements the URI class. URI objects can be used to access \
|
|
and manipulate the various components that make up these strings."
|
|
HOMEPAGE = "https://metacpan.org/dist/URI"
|
|
SECTION = "libs"
|
|
LICENSE = "Artistic-1.0 | GPL-1.0-or-later"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=d8ca5f628bf2cd180bc4fa044cb8ef41"
|
|
|
|
SRC_URI = "${CPAN_MIRROR}/authors/id/O/OA/OALDERS/URI-${PV}.tar.gz \
|
|
file://0001-Skip-TODO-test-cases-that-fail.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "5f7e42b769cb27499113cfae4b786c37d49e7c7d32dbb469602cd808308568f8"
|
|
|
|
S = "${WORKDIR}/URI-${PV}"
|
|
|
|
EXTRA_CPANFLAGS = "EXPATLIBPATH=${STAGING_LIBDIR} EXPATINCPATH=${STAGING_INCDIR}"
|
|
|
|
inherit cpan ptest-perl
|
|
|
|
do_compile() {
|
|
export LIBC="$(find ${STAGING_DIR_TARGET}/${base_libdir}/ -name 'libc-*.so')"
|
|
cpan_do_compile
|
|
}
|
|
|
|
do_install:prepend() {
|
|
# these tests require "-T" (taint) command line option
|
|
rm -rf ${B}/t/cwd.t
|
|
rm -rf ${B}/t/file.t
|
|
}
|
|
|
|
RDEPENDS:${PN} += "\
|
|
perl-module-integer \
|
|
perl-module-mime-base64 \
|
|
"
|
|
|
|
RDEPENDS:${PN}-ptest += " \
|
|
libtest-fatal-perl \
|
|
libtest-needs-perl \
|
|
libtest-warnings-perl \
|
|
perl-module-encode \
|
|
perl-module-encode-encoding \
|
|
perl-module-extutils-makemaker \
|
|
perl-module-extutils-mm-unix \
|
|
perl-module-file-spec-functions \
|
|
perl-module-net-domain \
|
|
perl-module-perlio \
|
|
perl-module-perlio-encoding \
|
|
perl-module-test \
|
|
perl-module-test-more \
|
|
perl-module-utf8 \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native"
|