mirror of
https://git.yoctoproject.org/poky
synced 2026-03-06 15:29:40 +01:00
102927a527
Integrating the following commit(s) to linux-yocto/6.6:
1/1 [
Author: Ross Burton
Email: ross.burton@arm.com
Subject: arm64: defconfig: remove CONFIG_IPQ_APSS_5018
Date: Thu, 4 Jan 2024 13:32:41 +0000
This was added in 7f0c873 ("Enable IPQ5018 SoC base configs"), but there
is no IPQ_APSS_5018 config defined in the kconfig at present.
Signed-off-by: Ross Burton <ross.burton@arm.com>
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
]
(From OE-Core rev: f660af767aacb39d7a9b97d7f0de8e5244012608)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
2.1 KiB
BlitzBasic
49 lines
2.1 KiB
BlitzBasic
KBRANCH ?= "v6.6/standard/preempt-rt/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# CVE exclusions
|
|
include recipes-kernel/linux/cve-exclusion_6.6.inc
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
|
# to build multiple virtual/kernel providers, e.g. as dependency of
|
|
# core-image-rt-sdk, core-image-rt.
|
|
python () {
|
|
if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
|
|
raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
|
|
}
|
|
|
|
SRCREV_machine ?= "bfa11b7b82a8d7a3c3f5a30813a8471be20449ab"
|
|
SRCREV_meta ?= "11390e802ca72f3549b9356f036b17e54afd7a34"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine;protocol=https \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.6;destsuffix=${KMETA};protocol=https"
|
|
|
|
LINUX_VERSION ?= "6.6.9"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
|
|
PV = "${LINUX_VERSION}+git"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
LINUX_KERNEL_TYPE = "preempt-rt"
|
|
|
|
COMPATIBLE_MACHINE = "^(qemux86|qemux86-64|qemuarm|qemuarmv5|qemuarm64|qemuppc|qemumips)$"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "arm/versatile-pb.dtb"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
|
KERNEL_FEATURES:append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
|