mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
11d9127ac5
PowerPC toolchains can use the OS "linux" or "linux-gnuspe". This patch links them together so the one cross-canadian toolchain can support both. GCC_FOR_TARGET is set for the GCC recipe as otherwise configure can pick up an incorrect value. [YOCTO #5354] (From OE-Core master rev: a1d6331238982b0c5d39b0a18794f6654b00d46a) (From OE-Core rev: b114b045687776ebc5c805e1f19758e7e37eebf2) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.1 KiB
PHP
37 lines
1.1 KiB
PHP
inherit cross-canadian
|
|
inherit python-dir
|
|
|
|
DESCRIPTION = "cross-canadian gdb for ${TARGET_ARCH} target - GNU debugger"
|
|
PN = "gdb-cross-canadian-${TRANSLATED_TARGET_ARCH}"
|
|
BPN = "gdb"
|
|
|
|
DEPENDS = "nativesdk-ncurses nativesdk-expat nativesdk-gettext nativesdk-readline nativesdk-python"
|
|
RDEPENDS_${PN} += "nativesdk-python-core nativesdk-python-lang nativesdk-python-re \
|
|
nativesdk-python-codecs nativesdk-python-netclient"
|
|
|
|
GDBPROPREFIX = "--program-prefix='${TARGET_PREFIX}'"
|
|
|
|
EXTRA_OECONF_append = "--with-python=${WORKDIR}/python"
|
|
|
|
do_configure_prepend() {
|
|
cat > ${WORKDIR}/python << EOF
|
|
#! /bin/sh
|
|
case "\$2" in
|
|
--includes) echo "-I${STAGING_INCDIR}/${PYTHON_DIR}/" ;;
|
|
--ldflags) echo "-Wl,-rpath-link,${STAGING_LIBDIR}/.. -Wl,-rpath,${libdir}/.. -lpthread -ldl -lutil -lm -lpython${PYTHON_BASEVERSION}" ;;
|
|
--exec-prefix) echo "${exec_prefix}" ;;
|
|
*) exit 1 ;;
|
|
esac
|
|
exit 0
|
|
EOF
|
|
chmod +x ${WORKDIR}/python
|
|
}
|
|
|
|
# we don't want gdb to provide bfd/iberty/opcodes, which instead will override the
|
|
# right bits installed by binutils.
|
|
do_install_append() {
|
|
rm -rf ${D}${exec_prefix}/lib
|
|
cross_canadian_bindirlinks
|
|
}
|
|
|