mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
b327b194f0
* causes libargp test to fail: http://errors.yoctoproject.org/Errors/Details/766951/ | configure: error: in '/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/build': | configure: error: libargp disabled and libc does not have argp config.log shows: configure:8424: x86_64-webos-linux-gcc -m64 -march=nehalem -mtune=generic -mfpmath=sse -msse4.2 --sysroot=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot -o conftest -O2 -pipe -g -feliminate-unused-debug-types -fcanon-prefix-map -fmacro-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/git=/usr/src/debug/rng-tools/6.16 -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/git=/usr/src/debug/rng-tools/6.16 -fmacro-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/build=/usr/src/debug/rng-tools/6.16 -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/build=/usr/src/debug/rng-tools/6.16 -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot= -fmacro-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot= -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot-native= -DJENT_CONF_ENABLE_INTERNAL_TIMER -Wl,-O1 -Wl,--hash-style=gnu -Wl,--as-needed -fcanon-prefix-map -fmacro-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/git=/usr/src/debug/rng-tools/6.16 -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/git=/usr/src/debug/rng-tools/6.16 -fmacro-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/build=/usr/src/debug/rng-tools/6.16 -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/build=/usr/src/debug/rng-tools/6.16 -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot= -fmacro-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot= -fdebug-prefix-map=/OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot-native= conftest.c -ljitterentropy >&5 conftest.c: In function 'main': conftest.c:51:52: error: passing argument 3 of 'argp_parse' from incompatible pointer type [-Wincompatible-pointer-types] 51 | int argc=1; char *argv={"test"}; argp_parse(0,argc,argv,0,0,0); return 0; | ^~~~ | | | char * In file included from conftest.c:47: /OE/build/luneos-styhead/tmp-glibc/work/qemux86_64-webos-linux/rng-tools/6.16/recipe-sysroot/usr/include/argp.h:371:58: note: expected 'char ** restrict' but argument is of type 'char *' 371 | int __argc, char **__restrict __argv, | ~~~~~~~~~~~~~~~~~~^~~~~~ (From OE-Core rev: 656b76a59f06e432d5dc6c9e8b76cdcda0113eb2) Signed-off-by: Martin Jansa <martin.jansa@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 78d9cad294f335f6e5b18b0ca790a9e5723f0c41) Signed-off-by: Steve Sakoman <steve@sakoman.com>
74 lines
2.6 KiB
BlitzBasic
74 lines
2.6 KiB
BlitzBasic
SUMMARY = "Random number generator daemon"
|
|
DESCRIPTION = "Check and feed random data from hardware device to kernel"
|
|
HOMEPAGE = "https://github.com/nhorman/rng-tools"
|
|
BUGTRACKER = "https://github.com/nhorman/rng-tools/issues"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
DEPENDS = "openssl libcap"
|
|
|
|
SRC_URI = "git://github.com/nhorman/rng-tools.git;branch=master;protocol=https \
|
|
file://init \
|
|
file://default \
|
|
file://rng-tools.service \
|
|
"
|
|
SRCREV = "e061c313b95890eb5fa0ada0cd6eec619dafdfe2"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools update-rc.d systemd pkgconfig
|
|
|
|
EXTRA_OECONF = "--without-rtlsdr"
|
|
|
|
PACKAGECONFIG ??= "libjitterentropy"
|
|
PACKAGECONFIG:libc-musl = "libargp libjitterentropy"
|
|
|
|
PACKAGECONFIG[libargp] = "--with-libargp,--without-libargp,argp-standalone,"
|
|
PACKAGECONFIG[libjitterentropy] = "--enable-jitterentropy,--disable-jitterentropy,libjitterentropy"
|
|
PACKAGECONFIG[libp11] = "--with-pkcs11,--without-pkcs11,libp11 openssl"
|
|
PACKAGECONFIG[nistbeacon] = "--with-nistbeacon,--without-nistbeacon,curl libxml2"
|
|
PACKAGECONFIG[qrypt] = "--with-qrypt,--without-qrypt,curl"
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}-service"
|
|
INITSCRIPT_NAME:${PN}-service = "rng-tools"
|
|
INITSCRIPT_PARAMS:${PN}-service = "start 03 2 3 4 5 . stop 30 0 6 1 ."
|
|
|
|
SYSTEMD_PACKAGES = "${PN}-service"
|
|
SYSTEMD_SERVICE:${PN}-service = "rng-tools.service"
|
|
|
|
CFLAGS += " -DJENT_CONF_ENABLE_INTERNAL_TIMER "
|
|
|
|
PACKAGES =+ "${PN}-service"
|
|
|
|
FILES:${PN}-service += " \
|
|
${sysconfdir}/init.d/rng-tools \
|
|
${sysconfdir}/default/rng-tools \
|
|
"
|
|
|
|
# Refer autogen.sh in rng-tools
|
|
do_configure:prepend() {
|
|
cp ${S}/README.md ${S}/README
|
|
}
|
|
|
|
do_install:append() {
|
|
install -Dm 0644 ${WORKDIR}/default ${D}${sysconfdir}/default/rng-tools
|
|
install -Dm 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/rng-tools
|
|
install -Dm 0644 ${WORKDIR}/rng-tools.service \
|
|
${D}${systemd_system_unitdir}/rng-tools.service
|
|
sed -i \
|
|
-e 's,@SYSCONFDIR@,${sysconfdir},g' \
|
|
-e 's,@SBINDIR@,${sbindir},g' \
|
|
${D}${sysconfdir}/init.d/rng-tools \
|
|
${D}${systemd_system_unitdir}/rng-tools.service
|
|
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'nistbeacon', 'yes', 'no', d)}" = "yes" ]; then
|
|
sed -i \
|
|
-e '/^IPAddressDeny=any/d' \
|
|
-e '/^RestrictAddressFamilies=/ s/$/ AF_INET AF_INET6/' \
|
|
${D}${systemd_system_unitdir}/rng-tools.service
|
|
fi
|
|
}
|
|
|
|
# libargp detection fails
|
|
# http://errors.yoctoproject.org/Errors/Details/766951/
|
|
CFLAGS += "-Wno-error=incompatible-pointer-types"
|