mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
1d640c9436
Most of the files that end up in the gcc include dir and other misc files scattered throughout the install get the build users uid and gid. (From OE-Core rev: db99a65b3e93dfacc27ea821c788f15b5de3a497) Signed-off-by: Mark Hatle <mark.hatle@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.5 KiB
PHP
55 lines
1.5 KiB
PHP
INHIBIT_PACKAGE_STRIP = "1"
|
|
|
|
# Having anything auto depending on gcc-cross-sdk is a really bad idea...
|
|
EXCLUDE_FROM_SHLIBS = "1"
|
|
|
|
PACKAGES = "${PN} ${PN}-doc"
|
|
|
|
FILES_${PN} = "\
|
|
${bindir}/* \
|
|
${libexecdir}/gcc/${TARGET_SYS}/${BINV}/* \
|
|
${gcclibdir}/${TARGET_SYS}/${BINV}/*.o \
|
|
${gcclibdir}/${TARGET_SYS}/${BINV}/specs \
|
|
${gcclibdir}/${TARGET_SYS}/${BINV}/lib* \
|
|
${gcclibdir}/${TARGET_SYS}/${BINV}/include \
|
|
${gcclibdir}/${TARGET_SYS}/${BINV}/include-fixed \
|
|
${includedir}/c++/${BINV} \
|
|
${prefix}/${TARGET_SYS}/bin/* \
|
|
${prefix}/${TARGET_SYS}/lib/* \
|
|
${prefix}/${TARGET_SYS}/usr/include/* \
|
|
"
|
|
FILES_${PN}-doc = "\
|
|
${infodir} \
|
|
${mandir} \
|
|
${gcclibdir}/${TARGET_SYS}/${BINV}/include/README \
|
|
"
|
|
|
|
do_install () {
|
|
oe_runmake 'DESTDIR=${D}' install-host
|
|
|
|
# Cleanup some of the ${libdir}{,exec}/gcc stuff ...
|
|
rm -r ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/install-tools
|
|
rm -r ${D}${libexecdir}/gcc/${TARGET_SYS}/${BINV}/install-tools
|
|
|
|
# We care about g++ not c++
|
|
rm -f ${D}${bindir}/*c++
|
|
|
|
# We don't care about the gcc-<version> copies
|
|
rm -f ${D}${bindir}/*gcc-?.?*
|
|
|
|
# We use libiberty from binutils
|
|
rm -f ${D}${prefix}/${TARGET_SYS}/lib/libiberty.a
|
|
rm -f ${D}${libdir}/libiberty.a
|
|
|
|
# Insert symlinks into libexec so when tools without a prefix are searched for, the correct ones are
|
|
# found.
|
|
dest=${D}${libexecdir}/gcc/${TARGET_SYS}/${BINV}/
|
|
install -d $dest
|
|
for t in ar as ld nm objcopy objdump ranlib strip g77 gcc cpp gfortran; do
|
|
ln -sf ${bindir}/${TARGET_PREFIX}$t $dest$t
|
|
done
|
|
|
|
chown -R root:root ${D}
|
|
}
|
|
|