mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 16:56:37 +01:00
760e81678c
* This is converging the recipes for go from meta-virtualization and oe-meta-go * Add recipes for go 1.7 * go.bbclass is added to ease out writing recipes for go packages * go-examples: Add an example, helloworld written in go This should serve as temlate for writing go recipes * Disable for musl, at least for now * Disable for x32/ppc32 which is not supported (From OE-Core rev: 78615e9260fb5d6569de4883521b049717fa4340) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.7 KiB
Plaintext
51 lines
1.7 KiB
Plaintext
BUILD_GOOS = "${@go_map_os(d.getVar('BUILD_OS', True), d)}"
|
|
BUILD_GOARCH = "${@go_map_arch(d.getVar('BUILD_ARCH', True), d)}"
|
|
BUILD_GOTUPLE = "${BUILD_GOOS}_${BUILD_GOARCH}"
|
|
HOST_GOOS = "${@go_map_os(d.getVar('HOST_OS', True), d)}"
|
|
HOST_GOARCH = "${@go_map_arch(d.getVar('HOST_ARCH', True), d)}"
|
|
HOST_GOARM = "${@go_map_arm(d.getVar('HOST_ARCH', True), d.getVar('TUNE_FEATURES', True), d)}"
|
|
HOST_GOTUPLE = "${HOST_GOOS}_${HOST_GOARCH}"
|
|
TARGET_GOOS = "${@go_map_os(d.getVar('TARGET_OS', True), d)}"
|
|
TARGET_GOARCH = "${@go_map_arch(d.getVar('TARGET_ARCH', True), d)}"
|
|
TARGET_GOARM = "${@go_map_arm(d.getVar('TARGET_ARCH', True), d.getVar('TUNE_FEATURES', True), d)}"
|
|
TARGET_GOTUPLE = "${TARGET_GOOS}_${TARGET_GOARCH}"
|
|
GO_BUILD_BINDIR = "${@['bin/${HOST_GOTUPLE}','bin'][d.getVar('BUILD_GOTUPLE',True) == d.getVar('HOST_GOTUPLE',True)]}"
|
|
|
|
def go_map_arch(a, d):
|
|
import re
|
|
if re.match('i.86', a):
|
|
return '386'
|
|
elif a == 'x86_64':
|
|
return 'amd64'
|
|
elif re.match('arm.*', a):
|
|
return 'arm'
|
|
elif re.match('aarch64.*', a):
|
|
return 'arm64'
|
|
elif re.match('mips64el*', a):
|
|
return 'mips64le'
|
|
elif re.match('mips64*', a):
|
|
return 'mips64'
|
|
elif re.match('mipsel*', a):
|
|
return 'mipsle'
|
|
elif re.match('mips*', a):
|
|
return 'mips'
|
|
elif re.match('p(pc|owerpc)(64)', a):
|
|
return 'ppc64'
|
|
elif re.match('p(pc|owerpc)(64el)', a):
|
|
return 'ppc64le'
|
|
else:
|
|
raise bb.parse.SkipPackage("Unsupported CPU architecture: %s" % a)
|
|
|
|
def go_map_arm(a, f, d):
|
|
import re
|
|
if re.match('arm.*', a) and re.match('arm.*7.*', f):
|
|
return '7'
|
|
return ''
|
|
|
|
def go_map_os(o, d):
|
|
if o.startswith('linux'):
|
|
return 'linux'
|
|
return o
|
|
|
|
|