mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
149ad2c3e2
In Libgcrypt 1.8.4, the C implementation of AES is vulnerable to a flush-and-reload side-channel attack because physical addresses are available to other processes. (The C implementation is used on platforms where an assembly-language implementation is unavailable.) Reference: https://nvd.nist.gov/vuln/detail/CVE-2019-12904 Patches from:1374254c29daedbbb554a4c561aab1(From OE-Core rev: 757f2d50d7cd194e5f734a24e68d8f0da98b38f8) Signed-off-by: Yi Zhao <yi.zhao@windriver.com> Signed-off-by: Ross Burton <ross.burton@intel.com> (cherry picked from commit 37e390ff05b6a4509019db358ed496731d80cc51) Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
2.2 KiB
BlitzBasic
58 lines
2.2 KiB
BlitzBasic
SUMMARY = "General purpose cryptographic library based on the code from GnuPG"
|
|
HOMEPAGE = "http://directory.fsf.org/project/libgcrypt/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
SECTION = "libs"
|
|
|
|
# helper program gcryptrnd and getrandom are under GPL, rest LGPL
|
|
LICENSE = "GPLv2+ & LGPLv2.1+ & GPLv3+"
|
|
LICENSE_${PN} = "LGPLv2.1+"
|
|
LICENSE_${PN}-dev = "GPLv2+ & LGPLv2.1+"
|
|
LICENSE_dumpsexp-dev = "GPLv3+"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff \
|
|
file://LICENSES;md5=840e3bcb754e5046ffeda7619034cbd8"
|
|
|
|
DEPENDS = "libgpg-error"
|
|
|
|
UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
|
|
SRC_URI = "${GNUPG_MIRROR}/libgcrypt/libgcrypt-${PV}.tar.bz2 \
|
|
file://0001-Add-and-use-pkg-config-for-libgcrypt-instead-of-conf.patch \
|
|
file://0003-tests-bench-slope.c-workaround-ICE-failure-on-mips-w.patch \
|
|
file://0002-libgcrypt-fix-building-error-with-O2-in-sysroot-path.patch \
|
|
file://0004-tests-Makefile.am-fix-undefined-reference-to-pthread.patch \
|
|
file://0001-Prefetch-GCM-look-up-tables.patch \
|
|
file://0002-AES-move-look-up-tables-to-.data-section-and-unshare.patch \
|
|
file://0003-GCM-move-look-up-table-to-.data-section-and-unshare-.patch \
|
|
"
|
|
SRC_URI[md5sum] = "fbfdaebbbc6d7e5fbbf6ffdb3e139573"
|
|
SRC_URI[sha256sum] = "f638143a0672628fde0cad745e9b14deb85dffb175709cacc1f4fe24b93f2227"
|
|
|
|
BINCONFIG = "${bindir}/libgcrypt-config"
|
|
|
|
inherit autotools texinfo binconfig-disabled pkgconfig
|
|
|
|
EXTRA_OECONF = "--disable-asm"
|
|
EXTRA_OEMAKE_class-target = "LIBTOOLFLAGS='--tag=CC'"
|
|
|
|
PACKAGECONFIG ??= "capabilities"
|
|
PACKAGECONFIG[capabilities] = "--with-capabilities,--without-capabilities,libcap"
|
|
|
|
do_configure_prepend () {
|
|
# Else this could be used in preference to the one in aclocal-copy
|
|
rm -f ${S}/m4/gpg-error.m4
|
|
}
|
|
|
|
# libgcrypt.pc is added locally and thus installed here
|
|
do_install_append() {
|
|
install -d ${D}/${libdir}/pkgconfig
|
|
install -m 0644 ${B}/src/libgcrypt.pc ${D}/${libdir}/pkgconfig/
|
|
}
|
|
|
|
PACKAGES =+ "dumpsexp-dev"
|
|
|
|
FILES_${PN}-dev += "${bindir}/hmac256"
|
|
FILES_dumpsexp-dev += "${bindir}/dumpsexp"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|