mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 02:03:04 +01:00
e5a85ac2e4
Ensure the following results in the kernel being rebuilt, repackaged and re-deployed in the final step: bitbake virtual/kernel bitbake -c menuconfig virtual/kernel [ make changes to the kernel configuration and save ] bitbake virtual/kernel If there are no changes to the configuration saved, the rebuild will not be triggered. Note that this relies on a function recently added to BitBake and requires full hashing (i.e. BB_SIGNATURE_HANDLER must be set to a signature handler that inherits from BasicHash) - if this is not the case or the function is not available in the version of BitBake being used this change will do nothing. Fixes [YOCTO #2256]. (From OE-Core rev: 9bf6b60e1599cf5dd87089d42584583cdfd6807a) (From OE-Core rev: a9600e68e64a111be4cb934e14b914fa553b5654) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
34 lines
902 B
Plaintext
34 lines
902 B
Plaintext
cml1_do_configure() {
|
|
set -e
|
|
unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
|
|
oe_runmake oldconfig
|
|
}
|
|
|
|
EXPORT_FUNCTIONS do_configure
|
|
addtask configure after do_unpack do_patch before do_compile
|
|
|
|
inherit terminal
|
|
|
|
python do_menuconfig() {
|
|
try:
|
|
mtime = os.path.getmtime(".config")
|
|
except OSError:
|
|
mtime = 0
|
|
|
|
oe_terminal("make menuconfig", '${PN} Configuration', d)
|
|
|
|
# FIXME this check can be removed when the minimum bitbake version has been bumped
|
|
if hasattr(bb.build, 'write_taint'):
|
|
try:
|
|
newmtime = os.path.getmtime(".config")
|
|
except OSError:
|
|
newmtime = 0
|
|
|
|
if newmtime > mtime:
|
|
bb.note("Configuration changed, recompile will be forced")
|
|
bb.build.write_taint('do_compile', d)
|
|
}
|
|
do_menuconfig[nostamp] = "1"
|
|
addtask menuconfig after do_configure
|
|
|