mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 09:16:36 +01:00
64df4e4aef
The class itself currently does nothing. The idea is to mark all recipes that make use of the texinfo utilities. In the future, this class could be used to suppress the generation/formatting of documentation for performance, explicitly track dependencies on these utilities, and eliminate Yocto's current dependency on the host system's texinfo utilities. (From OE-Core rev: e6fb2f9afe2ba6b676c46d1eb297ca9cc532d405) Signed-off-by: Max Eliaser <max.eliaser@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.3 KiB
PHP
45 lines
1.3 KiB
PHP
SUMMARY = "Flex (The Fast Lexical Analyzer)"
|
|
DESCRIPTION = "Flex is a fast lexical analyser generator. Flex is a tool for generating programs that recognize \
|
|
lexical patterns in text."
|
|
HOMEPAGE = "http://sourceforge.net/projects/flex/"
|
|
|
|
SECTION = "devel"
|
|
LICENSE = "BSD"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/flex/flex-${PV}.tar.bz2 \
|
|
file://run-ptest \
|
|
"
|
|
|
|
inherit autotools gettext texinfo ptest
|
|
|
|
|
|
M4 = "${bindir}/m4"
|
|
M4_class-native = "${STAGING_BINDIR_NATIVE}/m4"
|
|
|
|
EXTRA_OECONF += "ac_cv_path_M4=${M4}"
|
|
EXTRA_OEMAKE += "m4=${STAGING_BINDIR_NATIVE}/m4"
|
|
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}/${bindir}/flex M4=${M4}
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
create_wrapper ${D}/${bindir}/flex M4=${M4}
|
|
}
|
|
|
|
RDEPENDS_${PN} += "m4"
|
|
DEPENDS_${PN}-ptest += "bison-native flex-native"
|
|
|
|
do_compile_ptest() {
|
|
for i in `find ${S}/tests/ -type d |grep -Ev "concatenated-options|reject|table-opts" | awk -F/ '{print $NF}'`; \
|
|
do oe_runmake -C ${S}/tests/$i -f ${B}/tests/$i/Makefile top_builddir=${B} FLEX=flex $i; \
|
|
done
|
|
oe_runmake -C ${S}/tests/test-reject -f ${B}/tests/test-reject/Makefile top_builddir=${B} FLEX=flex test-reject-nr test-reject-r test-reject-ser test-reject-ver
|
|
}
|
|
|
|
do_install_ptest() {
|
|
for i in `find ${S}/tests/ -type d | awk -F/ '{print $NF}'`; \
|
|
do cp -r ${S}/tests/$i ${D}${PTEST_PATH}; \
|
|
done
|
|
}
|