mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 18:32:20 +02:00
39bd9fb72d
WARNING: QA Issue: nativesdk-libsdl: configure was passed unrecognised options: --disable-video-gem --disable-video-xbios --enable-dlopen --disable-debug --enable-endian The gem and xbios options exist but their helptext is wrong and there is no "video" in the name. This patch removes the now obsolete options and corrects the names of the others to match reality. (From OE-Core rev: 8cea5dd7d6804a8d739f5db6a5814ab6c802d538) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
67 lines
2.9 KiB
BlitzBasic
67 lines
2.9 KiB
BlitzBasic
SUMMARY = "Simple DirectMedia Layer"
|
|
DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \
|
|
library designed to provide low level access to audio, keyboard, mouse, \
|
|
joystick, 3D hardware via OpenGL, and 2D video framebuffer."
|
|
HOMEPAGE = "http://www.libsdl.org"
|
|
BUGTRACKER = "http://bugzilla.libsdl.org/"
|
|
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPLv2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=27818cd7fd83877a8e3ef82b82798ef4"
|
|
|
|
PROVIDES = "virtual/libsdl"
|
|
|
|
DEPENDS = "${@base_contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'opengl', 'virtual/libgl', '', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxext libxrandr libxrender', '', d)} \
|
|
tslib"
|
|
DEPENDS_class-nativesdk = "${@base_contains('DISTRO_FEATURES', 'x11', 'virtual/nativesdk-libx11 nativesdk-libxrandr nativesdk-libxrender nativesdk-libxext', '', d)}"
|
|
|
|
PR = "r2"
|
|
|
|
SRC_URI = "http://www.libsdl.org/release/SDL-${PV}.tar.gz \
|
|
file://configure_tweak.patch \
|
|
file://libsdl-1.2.15-xdata32.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/SDL-${PV}"
|
|
|
|
SRC_URI[md5sum] = "9d96df8417572a2afb781a7c4c811a85"
|
|
SRC_URI[sha256sum] = "d6d316a793e5e348155f0dd93b979798933fb98aa1edebcc108829d6474aad00"
|
|
|
|
inherit autotools lib_package binconfig pkgconfig
|
|
|
|
EXTRA_OECONF = "--disable-static --enable-cdrom --enable-threads --enable-timers \
|
|
--enable-file --disable-oss --disable-esd --disable-arts \
|
|
--disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
|
|
--disable-mintaudio --disable-nasm --disable-video-dga \
|
|
--disable-video-fbcon --disable-video-ps2gs --disable-video-ps3 \
|
|
--disable-xbios --disable-gem --disable-video-dummy \
|
|
--enable-input-events --enable-input-tslib --enable-pthreads \
|
|
${@base_contains('DISTRO_FEATURES', 'directfb', '--enable-video-directfb', '--disable-video-directfb', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'opengl', '--enable-video-opengl', '--disable-video-opengl', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', '--enable-video-x11', '--disable-video-x11', d)} \
|
|
--disable-video-svga \
|
|
--disable-video-picogui --disable-video-qtopia --enable-sdl-dlopen \
|
|
--disable-rpath \
|
|
--disable-pulseaudio"
|
|
|
|
PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}"
|
|
PACKAGECONFIG[alsa] = "--enable-alsa --disable-alsatest,--disable-alsa,alsa-lib,"
|
|
|
|
PARALLEL_MAKE = ""
|
|
|
|
EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader"
|
|
|
|
do_configure_prepend() {
|
|
# Remove old libtool macros.
|
|
MACROS="libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4"
|
|
for i in ${MACROS}; do
|
|
rm -f ${S}/acinclude/$i
|
|
done
|
|
export SYSROOT=$PKG_CONFIG_SYSROOT_DIR
|
|
}
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|